Come creare un gradiente di colore verticale (o qualsiasi altro angolo oltre ad un gradiente orizzontale piatta)

Question

Ciao a tutti, la mia prima volta cercando di disegnare un gradiente multicolore in ActionScript 3.

Così ho preso questo codice da Guida in docs , ma io non riesco a ottenere un gradiente verticale, qualunque sia la formula o il numero che uso per la rotazione, rimane bloccato sul gradiente orizzontale di default: (

My Code:

È possibile vedere nelle tracce del codice di rotazione ho provato ...

package
{
import flash.display.DisplayObject;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.MovieClip;
import flash.display.Graphics;
import flash.display.Sprite;
import flash.display.Shape;
import flash.geom.Matrix;
import flash.events.*;

public class MyGradient extends MovieClip
{
    private var colorHolder:MovieClip = new MovieClip();
    private var colorGrad:MovieClip = new MovieClip();
    private var fillType:String     = GradientType.LINEAR;
    private var colors:Array        = [0xFF0000, 0x4F8EEC];
    private var alphas:Array        = [1, 1];
    private var ratios:Array        = [0x00, 0xFF];
    private var matr:Matrix         = new Matrix();
    private var spreadMethod:String = SpreadMethod.PAD;


    public function MyGradient():void
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init():void
    {
        colorHolder = new MovieClip();
        colorGrad   = new MovieClip();

        //matr.rotate(30*Math.PI/180);
        //matr.rotate(45);
        //matr.rotate(90);
        //matr.rotate(Math.PI/90);
        matr.rotate(Math.PI/9);
        matr.createGradientBox(200, 200, 0, 0, 1);
        colorGrad.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod);        
        colorGrad.graphics.drawRect(0,0,200,200);

        colorHolder.addChild(colorGrad);
        addChild(colorHolder);
        }

    }

}

Fix attualizzato tramite pesantemente coinvolto :

matr.createGradientBox(200, 200, Math.PI/2, 0, 0);

Answer 1

Questa riga di codice imposta il valore di rotazione indietro a zero:

matr.createGradientBox(200, 200, 0, 0, 1);

Se si guardano le parametri accettati dalla funzione vedrete che il terzo parametro è la rotazione. Quindi, provare quanto segue:

matr.createGradientBox(200, 200, Math.PI/9, 0, 1);

Inoltre, non v'è alcun motivo che si sta traducendo il valore y di 1 pixel?

Spero che questo aiuti. Buona fortuna!

Answer 2

provare a cambiare l'ordine di questo 2 linee, quindi sarebbe:

matr.createGradientBox(200, 200, 0, 0, 1);
matr.rotate((Math.PI/180)*90);

Answer 3

Se stai facendo un sacco di disegno, si dovrebbe anche verificare degrafa.

http://www.degrafa.org/