Perché il numero di pagine in un documento Word è diverso in Perl e Word VBA?

Question

Ho un (set di) documenti Word per i quali sto cercando di ottenere varie proprietà (numero di pagine, autore, ecc.) usando Win32 :: OLE in Perl:

print $MSWord->Documents->Open($name)->
BuiltInDocumentProperties->{"Number of pages"}->value . " \n";

Questo restituisce 4 pagine. Ma il numero effettivo di pagine nel documento è 9. Il numero di pagine nella prima sezione è 4. Voglio il numero totale di pagine nel documento.

Se, all'interno di Word VBA, faccio quanto segue:

MsgBox ActiveDocument.BuiltInDocumentProperties("Number of pages")

Viene visualizzato 9. Il numero di pagine visualizzate nella pagina Proprietà / Statistiche è 9.

Devo forzare un ricalcolo? C'è un modo per chiedere alla libreria OLE di forzare un ricalcolo o devo trattare ogni sezione separatamente?

Sono su XP, Word 2007, ActivePerl v5.10.0.

Answer 1

#!/usr/bin/perl

use strict;
use warnings;

use File::Spec::Functions qw( catfile );

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Word';
$Win32::OLE::Warn = 3;

my $word = get_word();
$word->{Visible} = 1;

my $doc = $word->{Documents}->Open(catfile $ENV{TEMP}, 'test.doc');
$doc->Repaginate;

my $props = $doc->BuiltInDocumentProperties;
my $x = $props->Item(wdPropertyPages)->valof;
print "$x\n";

$doc->Close(0);

sub get_word {
    my $word;
    eval {
        $word = Win32::OLE->GetActiveObject('Word.Application');
    };

    die "$@\n" if $@;

    unless(defined $word) {
        $word = Win32::OLE->new('Word.Application', sub { <*>[0]->Quit })
            or die "Oops, cannot start Word: ", 
                   Win32::OLE->LastError, "\n";
    }
    return $word;
}