Batch / Windows: numeri casuali

Question

Sto sviluppando un gioco di carte per lotti. [fornirà un link quando fatto]

Fondamentalmente quello che voglio fare è 'impostare' '% random%' su '% numbs%.

set %numbs%=%random%

E poi voglio che l'utente digiti un valore dai% random% numeri visualizzati

echo %numbs%
Set nuchoo=
set /p nuchoo=Number: 

Qual è la mia domanda ora su come verificare se il valore digitato dall'utente è nel valore% numbs%. Se lo è,

GOTO :validnucho

in caso contrario,

GOTO :unvalidnucho

Quando va a: validnucho, dovrebbe cancellare quel numero da% numbs% var. Ovviamente importa se% numbs% var contiene il doppio del numero, quindi dovrebbe eliminare solo uno dei due. Il resto lo so.

Answer 1

Questo dovrebbe iniziare

Salva quanto segue come Instr.cmd

@echo off 

rem These two lines allow tracing to be turned on by entering 
rem set TRACE=ECHO on the cmd line
  if not defined TRACE set TRACE=rem
  %TRACE% on 

rem Allow use of delayed variable expansion using !  
  setlocal ENABLEDELAYEDEXPANSION 

  if  /I [%1]==[Test] ( 
    call :Test
    goto :eof
    )

:Instr 
  set mTestStr=%1

rem  set /a does arithmatic
  set /a TestIdx=0
  set Found=N
  set CopiedStr=

  :startLoop

rem extract character at index TestIndx to test   
    set TestedChar=!mTestStr:~%TestIdx%,1!
rem echo TestedChar if trace is on 
    %TRACE% %TestedChar%

    If [!TestedChar!]==[] (
      goto :exitInstr
    )

    If [%TestedChar%]==[%2] (
rem   Testedchar matchs search character, 
rem   so we have found the char we were looking for    
      if %Found%==Y (
        set CopiedStr=%CopiedStr%%TestedChar%
      ) 
      set Found=Y
    ) else (
      set CopiedStr=%CopiedStr%%TestedChar%
    ) 



rem Increment Index       
    SET /a TestIdx=TestIdx+1

  goto :startLoop

:exitInstr

rem endlocal but keep CopiedStr and Found
  endlocal & set CopiedStr=%CopiedStr% & set Found=%Found%

goto :eof

:Test    


  call :Instr abcde c
  call :Verify Y %Found% "call :Instr abcde c - Found"
  call :Verify abde, %CopiedStr% "call :Instr abcde c - CopiedStr"

  call :Instr abcde x
  call :Verify N %Found% "call :Instr abcde x - Found"
  call :Verify abcde, %CopiedStr% "call :Instr abcde x - CopiedStr"

  call :Instr abcdec c
  call :Verify Y %Found% "call :Instr abcdec c - Found"
  call :Verify abdec, %CopiedStr% "call :Instr abcdec c - CopiedStr"


    echo Tests Done

goto :eof   

:Verify
  set Expected=%1
  set Expected=%Expected:"=%

  set Actual=%2
  set Actual=%Actual:"=%

  set Msg=%3
  set Msg=%msg:"=%

  If not "%Expected%"=="%Actual%"   (
    echo Failed: Expected "%Expected%" but was "%Actual%"  - %Msg%
  ) else ( 
    echo OK Expected "%Expected%" - %Msg%
  )

goto :eof