Oracle: C'è un modo per ottenere recenti errori di sintassi SQL?

StackOverflow https://stackoverflow.com/questions/3468216

  •  28-09-2019
  •  | 
  •  

Domanda

stiamo assistendo a un sacco di "ORA-00936: mancanti espressione" errori nel nostro registro di applicazione. C'è un modo in Oracle per determinare quali statement (s) stanno fallendo?

Ho provato a interrogare v $ sql, ma queste affermazioni non sono inserite in questo punto di vista, dal momento che non passano i controlli di sintassi.

Il nostro C # applicazione utilizza LINQ per generare una query a un database Oracle. Questo lo rende un po 'difficile ottenere la query SQL dall'applicazione. Speravo ho potuto solo ottenere da Oracle più facile.

È stato utile?

Soluzione

È possibile creare un trigger in Oracle che registrerà tutti gli errori (o quasi tutti - NO_DATA_FOUND non è considerato un errore). Nell'esempio qui sotto, qualsiasi errore nello schema è registrato nella tabella TRACK_DETAIL (errore in una fila, fallito SQL nel seguente). È possibile rendere più sofisticato, con un numero di sequenza, data / ora, ecc. 

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

Ricordate di eliminare (o disattivare) il grilletto quando hai finito con esso.

Altri suggerimenti

Se è possibile attivare l'analisi SQL dal codice dell'applicazione in qualche modo (alter session set sql_trace = true), il bilancio verrà visualizzato nei file di traccia sul host del database.

Si potrebbe provare a utilizzare qualcosa come Wireshark sulla porta utilizzata per connettersi a Oracle per vedere quali istruzioni SQL vengono inviati. Potrebbe non essere la migliore risposta -. ma potrebbe arrivare dove devi andare più veloce

Prova soluzione di monitoraggio SQL da Kris Vandermotten blog .

Inoltre è possibile reindirizzare log con DataContext proprietà log : 

using (NorthwindDataContext context = new NorthwindDataContext())
{
  context.Log = Console.Out;
}

In alternativa, utilizzare altri strumenti di debug come LINQ to Entities Visualizer ...

Autorizzato sotto: CC-BY-SA insieme a attribuzione
Non affiliato a StackOverflow
scroll top