Oracle:最近のSQL構文エラーを取得する方法はありますか?
質問
アプリケーションログには、「ORA-00936:欠落式」エラーがたくさん見られます。 Oracleに、どの声明が失敗しているかを判断する方法はありますか?
v $ sqlのクエリを試みましたが、これらのステートメントは構文チェックに合格しないため、そのビューに挿入されていません。
C#アプリケーションはLINQを使用して、Oracleデータベースへのクエリを生成しています。これにより、アプリケーションからSQLクエリを取得することが少し難しくなります。 Oracleから簡単に入手できることを望んでいました。
解決
すべてのエラーを記録するトリガーをOracleに作成できます(またはほとんどすべて-NO_DATA_FOUNDはエラーとは見なされません)。以下の例では、スキーマのエラーはtrack_detailテーブルに記録されています(1つの行のエラー、次の行でSQLに失敗しました)。シーケンス番号、日付/時刻など、より洗練されることができます。
create table track_detail (val varchar2(4000));
create or replace procedure track (p_text IN VARCHAR2) IS
PRAGMA AUTONOMOUS_TRANSACTION;
begin
insert into track_detail(val)
values (p_text);
commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
v_num NUMBER;
v_sql_text ora_name_list_t;
begin
v_temp := translate(v_temp,'''','"');
track(v_temp);
v_num := ora_sql_txt(v_sql_text);
v_temp := null;
BEGIN
FOR i IN 1..v_num LOOP
v_temp := v_temp || v_sql_text(i);
END LOOP;
EXCEPTION
WHEN VALUE_ERROR THEN NULL;
END;
v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
track(v_temp);
end;
/
トリガーが終了したら、トリガーをドロップ(または無効にする)ことを忘れないでください。
他のヒント
アプリケーションコードからSQLトレースを有効にすることができる場合(セッションセットSQL_TRACE = trueを変更)、ステートメントはデータベースホストのトレースファイルに表示されます。
Oracleに接続するために使用されるポートでWiresharkのようなものを使用して、SQLステートメントが送信されているものを確認することを試みることができます。最良の答えではないかもしれませんが、それはあなたがより速く行くために必要な場所にあなたを得るかもしれません。
sql監視ソリューションを試してください Kris Vandermottenブログ.
また、ログをリダイレクトできます datacontext.logプロパティ :
using (NorthwindDataContext context = new NorthwindDataContext())
{
context.Log = Console.Out;
}
または、そのような他のデバッグツールを使用します linq to Entities Visualizer ...