Come aggiungere atributo @xml: base per i miei file XML?
Domanda
Ho bisogno di un foglio di stile per convertire i file XML DocBook in modo che ora includono un xml: elemento di base per i miei tag di sezione. Come posso fare per farlo (dal xml: base ha bisogno di sistema e di nodo informazioni ???)
Input:
<section xmlns="http://docbook.org/ns/docbook" xml:id="voidVisit" version="5">
<title>Void</title>
<section>
<title>Screenshot</title>
<mediaobject>
<imageobject>
<imagedata fileref="screenshots/Dialog.png" />
</imageobject>
</mediaobject>
</section>
</section>
Output:
...
<section xml:id="void" version="5"
xml:base="file:/C:/Projects/my/proj/trunk/spec/module/components/void.xml">
<title>Void</title>
<section>
<title>Screenshot</title>
<mediaobject>
<imageobject>
<imagedata fileref="screenshots/Dialog.png"/>
</imageobject>
</mediaobject>
</section>
...
Soluzione
In XSLT 2.0 (XPath 2.0) le funzioni static-base-uri()
e base-uri()
può essere utilizzato per tale scopo .
Ecco un esempio di lavoro:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes"/>
<xsl:template match="/">
<doc xml:base="{base-uri()}"/>
</xsl:template>
</xsl:stylesheet>
quando viene applicata questa trasformazione, il risultato voluto è prodotto :
<doc xml:base="file:/C:/CVS-DDN/fxsl-xslt2/data/marrowtr.xml"/>
Quindi, la completa trasformazione nel tuo caso è :
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:d="http://docbook.org/ns/docbook">
<xsl:output omit-xml-declaration="yes"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/d:section">
<xsl:copy>
<xsl:attribute name="xml:base" select="base-uri(/)"/>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
In XSLT 1.0 soluzione è per passare la base-uri come un parametro esterno (xsl:param>
globale) alla trasformazione.
Autorizzato sotto: CC-BY-SA insieme a attribuzione
Non affiliato a StackOverflow