OpenModelica - 書籍のサンプルを実行しようとしていますが、内部と外部の問題があります

StackOverflow https://stackoverflow.com/questions/19841314

  •  29-07-2022
  •  | 
  •  

質問

OpenModelica を実行しており、Modelica による物理モデリングの概要の例を実行しようとしています。例 9.1 ～ 9.4 をパッケージにコピーしました。ファイルは次のようになります。

    package gravityPackage
  //Test of gravity taken from Intro to Physical modeling with Modelica
  //
  //
  //
  //
  //
  model ParticleField
    inner function gravity = TwoBodyField;
    Particle p1(x_init = {2,-2,0}, v_init = {0.7,0,0});
    Particle p2(x_init = {0,0.5,0}, v_init = {-1,-1,0});
    Particle p3(x_init = {0.5,2,0}, v_init = {-1,-0.5,0});
  end ParticleField;
  function TwoBodyField
    extends GravityField;
  protected
    Modelica.SIunits.Position b1[3],b2[3];
    Modelica.SIunits.Velocity n1[3],n2[3];
  algorithm
    b1:={0,0,0};
    b2:={0,1,0};
    n1:=-(x - b1) / sqrt((x - b1) * (x - b1));
    n2:=-(x - b2) / sqrt((x - b2) * (x - b2));
    g:=n1 / ((x - b1) * (x - b1)) + n2 / ((x - b2) * (x - b2));
  end TwoBodyField;
  partial function GravityField
    input Modelica.SIunits.Position x[3];
    output Modelica.SIunits.Acceleration g[3];
  end GravityField;
  model Particle
    parameter Modelica.SIunits.Position x_init[3];
    parameter Modelica.SIunits.Velocity v_init[3];
  protected
    outer function gravity = GravityField;
    //outer function gravity=ParticleField;
    //outer function gravity=TwoBodyField;
    Modelica.SIunits.Position x[3](start = x_init);
    Modelica.SIunits.Velocity v[3](start = v_init);
    Modelica.SIunits.Acceleration a[3];
  equation
    v = der(x);
    a = der(v);
    a = gravity(x);
  end Particle;
end gravityPackage;

しかし、OMShell にアクセスして実行しようとすると、次の結果が得られます。

    >> loadFile("gravityPackage.mo")
true


>> simulate(gravityPackage.ParticleField) 
record SimulationResult
    resultFile = "",
    simulationOptions = "startTime = 0.0, stopTime = 1.0, numberOfIntervals = 500, tolerance = 0.000001, method = 'dassl', fileNamePrefix = 'gravityPackage.ParticleField', options = '', outputFormat = 'mat', variableFilter = '.*', measureTime = false, cflags = '', simflags = ''",
    messages = "Simulation failed for model: gravityPackage.ParticleField
[gravityPackage.mo:34:11-34:42:writable] Warning: No corresponding 'inner' declaration found for class gravity declared as 'outer '.
 Continuing flattening by only considering the 'outer' class declaration.
[gravityPackage.mo:43:5-43:19:writable] Error: Failed to instantiate equation 
a = gravity(x);.
Error: Error occurred while flattening model gravityPackage.ParticleField
",
    timeFrontend = 0.0,
    timeBackend = 0.0,
    timeSimCode = 0.0,
    timeTemplates = 0.0,
    timeCompile = 0.0,
    timeSimulation = 0.0,
    timeTotal = 0.0
end SimulationResult;

>>

したがって、明らかに、スコープに関連して、私が正しく理解していないことがあります。パッケージを除くすべてのコードは、書籍から直接コピーしたものです。単一のファイルにまとめるにはパッケージが必要だと思います (ただし、他の方法をいくつか試しましたが成功しませんでした)。ご提案をお待ちしております。

ありがとう、

役に立ちましたか？

解決

これはOpenModelicaのバグです。内部コンポーネントまたはクラスであるが、機能用ではない場合は正常に動作するはずです。

私はそれについてのバグレポートを追加しました、そして私たちはそれを修正します：https://trac.openmodelica.org/openmodelica/ticket/2467

今のところ、内側/外側のパッケージを使用できます。これは正常に動作するはずです。

package gravityPackage

package Functions
  function TwoBodyField
    extends GravityField;
  protected
    Modelica.SIunits.Position b1[3],b2[3];
    Modelica.SIunits.Velocity n1[3],n2[3];
  algorithm
    b1:={0,0,0};
    b2:={0,1,0};
    n1:=-(x - b1) / sqrt((x - b1) * (x - b1));
    n2:=-(x - b2) / sqrt((x - b2) * (x - b2));
    g:=n1 / ((x - b1) * (x - b1)) + n2 / ((x - b2) * (x - b2));
  end TwoBodyField;

  partial function GravityField
    input Modelica.SIunits.Position x[3];
    output Modelica.SIunits.Acceleration g[3];
  end GravityField;

end Functions;

model ParticleField
    inner package funcs = Functions;
    Particle p1(x_init = {2,-2,0}, v_init = {0.7,0,0});
    Particle p2(x_init = {0,0.5,0}, v_init = {-1,-1,0});
    Particle p3(x_init = {0.5,2,0}, v_init = {-1,-0.5,0});
  end ParticleField;

  model Particle
    parameter Modelica.SIunits.Position x_init[3];
    parameter Modelica.SIunits.Velocity v_init[3];
  protected
    outer package funcs = Functions;
    function gravity = funcs.TwoBodyField;
    //outer function gravity=ParticleField;
    //outer function gravity=TwoBodyField;
    Modelica.SIunits.Position x[3](start = x_init);
    Modelica.SIunits.Velocity v[3](start = v_init);
    Modelica.SIunits.Acceleration a[3];
  equation
    v = der(x);
    a = der(v);
    a = gravity(x);
  end Particle;

end gravityPackage;

他のヒント

OK、それで、ここでの問題は、動的スコープ（つまり、 inner そして outer）。この点に関する仕様はまだ読んでいませんが、これではうまくいかないと思います。理由は、通常、 inner そして outer インスタンス化されるもの (変数、モデルなど) と組み合わせて使用​​されます。

したがって、理解すべきことは、概念的には両方とも constant 変数と function 定義はインスタンス化されません。治療できること function インスタンス (ファーストクラスの値) として使用すると、いくつかの有益な結果が得られますが、意味上の複雑さも生じます。言語の最近のバージョンでは、関数を第一級市民として扱おうとする取り組みが行われてきました。主な使用例は、関数を引数として他の関数に渡すことでした。しかし、これらの新しいセマンティクスは、(あなたの例が示すように) 関数を真にファーストクラスの値にするには至っていないと思います。ただし、これは OpenModelica に問題がある可能性があります。断定的には言えません。

これに対処する 1 つの方法は、replaceable と redeclare を使用することです。だからあなたの中で Particle モデル、定義 gravity このような：

public
  replaceable function gravity = GravityField;

次に、次のようにインスタンス化します。

model ParticleField
  Particle p1(x_init = {2,-2,0}, v_init = {0.7,0,0}, redeclare function gravity = TwoBodyField);
  Particle p2(x_init = {0,0.5,0}, v_init = {-1,-1,0}, redeclare function gravity = TwoBodyField);
  Particle p3(x_init = {0.5,2,0}, v_init = {-1,-0.5,0}, redeclare function gravity = TwoBodyField);
end ParticleField;

私はこのソリューションをテストしていないことに注意してください。たとえば、あなたの Particle モデルには partial 修飾子 (オーバーライドする必要があるため) gravity 非partial 実装）。

それが役立つことを願っています。

ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top