ODTオープンオフィスドキュメントで検索して交換する方法は？

Question

私のDelphiアプリケーションでは、現在、Office OLE Automationを使用してDOCおよびDOCXワードドキュメントをプログラムで検索して交換しています。オープンオフィスで同じことをするコード（doc、docs、odt）を持っている人はいますか？

私も尋ねました PDFへの保存に関する関連する質問.

Answer 1

焦点を当てる必要があります XREPLACEABLE インターフェース。これが例です。エラー処理はないことに注意してください。 Libreofficeのライターでテストしましたが、私にとってはうまくいきます。

uses
  ComObj;

procedure OpenOfficeReplace(const AFileURL: string; ASearch: string; const AReplace: string);
var
  StarOffice: Variant;
  StarDesktop: Variant;
  StarDocument: Variant;
  FileReplace: Variant;
  FileParams: Variant;
  FileProperty: Variant;

begin
  StarOffice := CreateOleObject('com.sun.star.ServiceManager');
  StarDesktop := StarOffice.CreateInstance('com.sun.star.frame.Desktop');

  FileParams := VarArrayCreate([0, 0], varVariant);
  FileProperty := StarOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue');
  FileProperty.Name := 'Hidden';
  FileProperty.Value := False;
  FileParams[0] := FileProperty;

  StarDocument := StarDesktop.LoadComponentFromURL(AFileURL, '_blank', 0, FileParams);

  FileReplace := StarDocument.CreateReplaceDescriptor;
  FileReplace.SearchCaseSensitive := False;
  FileReplace.SetSearchString(ASearch);
  FileReplace.SetReplaceString(AReplace);

  StarDocument.ReplaceAll(FileReplace);

  ShowMessage('Replace has been finished');

  StarDocument.Close(True);
  StarDesktop.Terminate;
  StarOffice := Unassigned;
end;

および例の使用

procedure TForm1.Button1Click(Sender: TObject);
begin
  OpenOfficeReplace('file:///C:/File.odt', 'Search', 'Replace');
end;

また、いくつかの検索/交換オプションがあります SearchDescriptor.