appendall-リスト内のすべてのリストにリストを追加する

Question

リスト内のすべてのリストにリストを追加する方法を見つけようとしています。

何かのようなもの：

appendAll([a,b],[[q,w],[z,x]],X).
X = [[a,b,q,w],[a,b,z,x]].

私はまだプロログに慣れていないので、ネストされたリストは私をかなり捨てています。

私はこれを数時間見つめています：

appendAll([], _, []).
appendAll(_, [], []).
appendAll([H1|T1], [H2|T2], X) :-
  append(H1,H2,R),
  appendAll(T1,[H2|T2],X).
  % recurse down to [], and append back up

どんな助けも感謝しています！

Answer 1

Prologを使用してプログラミングするのが難しいのは、実際の再帰パターンに慣れて特定することです。多くの場合、再帰で直接考えるのではなく、ここですべてのコンストラクトの簡単なものが機能する可能性があるかどうかを尋ねることが最善です。

この場合、リストのリストとリストの別のリストとの関係が必要です。要素は互いの要素に対応するため、どちらも同じ長さです。

appendAll(Prefix, Lists, Prefixedlists) :-
    maplist(append(Prefix), Lists, Prefixedlists).

述語 maplist/3 多くのプロログシステムで定義されています。そうでない場合は、ISO適合システムでそのように定義します。

maplist(_Cont_2, [], []).
maplist(Cont_2, [X|Xs], [Y|Ys]) :-
   call(Cont_2, X, Y),
   maplist(Cont_2, Xs, Ys).

プレーンな述語と同じです：

maplist_append(Prefix, [], []).
maplist_append(Prefix, [X|Xs], [Y|Ys]) :-
   append(Prefix, X, Y),
   maplist_append(Prefix, Xs, Ys).