人生のゲームを最適化します
-
28-10-2019 - |
質問
私はMathematicaでLife of Lifeプログラムを書いていますが、細胞の一部に複製ルールを適用できる必要があるという警告があります。Mapatを使用して新しい方法を試してみたいが、LiveNeighborsは機能しませんElementWise、そして私が以前にやったことを正確に実行せずにそれを修正する方法を考えることはできません(乱雑なインデックスがたくさんあります)、誰かが提案をしていますか? (これは以下にリストされている古い方法よりも効率的であると思っています。
私がやろうとしていること:
Map[ArrayPlot,FixedPointList[MapAt[update[#,liveNeighbors[#]]&,#,coords]&,Board, 1]]
私がすでにしたこと:
LifeGame[ n_Integer?Positive, steps_] := Module [{Board, liveNeighbors, update},
Board = Table [Random [Integer], {n}, {n}];
liveNeighbors[ mat_] :=
Apply[Plus,Map[RotateRight[mat,#]&,{{-1,-1},{-1, 0},{-1,1}, {0, -1}, {0, 1}, {1, -1}, {1, 0}, {1, 1}}]];
update[1, 2] := 1;
update[_, 3] := 1;
update[ _, _] := 0;
SetAttributes[update, Listable];
Seed = RandomVariate[ProbabilityDistribution[0.7 UnitStep[x] + 0.3 UnitStep[x - 1], {x, 0, 1, 1}], {n, n}];
FixedPointList[Table[If[Seed[[i, j]] == 1,update[#[[i, j]], liveNeighbors[#][[i, j]]],#[[i, j]]], {i, n}, {j, n}]&, Board, steps]]]
ありがとう!
解決
In[156]:=
LifeGame2[n_Integer?Positive, steps_] :=
Module[{Board, liveNeighbors, update},
Board = RandomInteger[1, {n, n}];
liveNeighbors[mat_] :=
ListConvolve[{{1, 1, 1}, {1, 0, 1}, {1, 1, 1}},
ArrayPad[mat, 1, "Periodic"]];
SetAttributes[update, Listable];
Seed = RandomVariate[BernoulliDistribution[0.3], {n, n}];
update[0, el_, nei_] := el;
update[1, 1, 2] := 1;
update[1, _, 3] := 1;
update[1, _, _] := 0;
FixedPointList[MapThread[update, {Seed, #, liveNeighbors[#]}, 2] &,
Board, steps]
]
この実装はあなたと同じことをしますが、はるかに高速です。
In[162]:= AbsoluteTiming[
res1 = BlockRandom[SeedRandom[11]; LifeGame[20, 100]];]
Out[162]= {6.3476347, Null}
In[163]:= Timing[BlockRandom[Seed[11]; LifeGame2[20, 100]] == res1]
Out[163]= {0.047, True}
他のヒント
宿題の問題のために自分のコードをロールする必要がないと仮定して、組み込みを使用することを検討したことがありますか CellularAutomaton
関数?
ドキュメントから直接、2D CAルール:
GameOfLife = {224, {2, {{2, 2, 2}, {2, 1, 2}, {2, 2, 2}}}, {1, 1}};
100x100グリッドを100ステップで繰り返します。
ArrayPlot[CellularAutomaton[GameOfLife, RandomInteger[1, {100, 100}], {{{100}}}]]
少なくとも速度比較のためのベースラインを提供します。
それ以外の MapAt
, 、使用できます Part
とともに Span
サブアレイ全体を一度に置き換える構文:
a = ConstantArray[0, {5, 5}];
a[[2 ;; 4, 2 ;; 4]] = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}
hth!
所属していません StackOverflow