Delphi CreateProcessコマンドから返された文字列にアクセスできますか？

StackOverflow https://stackoverflow.com/questions/343476

質問

Win32 CreateProcess関数を使用して、外部実行可能ファイルへの呼び出しを実行しています。実行可能ファイルは文字列を返します。

実行可能ファイルを呼び出した後、返された文字列をキャプチャして問い合わせる方法はありますか？それに失敗すると、実行可能ファイル内のファイルに文字列を書き出して、呼び出しが終了した後に呼び出しプログラムでそれを読み取る必要があります。しかし、それは下手に見えます。

役に立ちましたか？

解決

Jediコードライブラリには、プロセスを実行するCreateDOSProcessRedirected関数が含まれています。入力ファイルと出力ファイルを提供します。必要な入力（ある場合）を入力ファイルに入れ、プロセスの出力（ある場合）を出力ファイル（プロセスの完了後）から読み取ることができます。

これは、 JCL での実装方法です。 

function CreateDOSProcessRedirected(const CommandLine, InputFile, OutputFile: string): Boolean;
var
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  SecAtrrs: TSecurityAttributes;
  hInputFile, hOutputFile: THandle;
begin
  Result := False;
  hInputFile := CreateFile(PChar(InputFile), GENERIC_READ, FILE_SHARE_READ,
    CreateInheritable(SecAtrrs), OPEN_EXISTING, FILE_ATTRIBUTE_TEMPORARY, 0);
  if hInputFile <> INVALID_HANDLE_VALUE then
  begin
    hOutputFile := CreateFile(PChar(OutPutFile), GENERIC_READ or GENERIC_WRITE,
      FILE_SHARE_READ, CreateInheritable(SecAtrrs), CREATE_ALWAYS,
      FILE_ATTRIBUTE_TEMPORARY, 0);
    if hOutputFile <> INVALID_HANDLE_VALUE then
    begin
      FillChar(StartupInfo, SizeOf(StartupInfo), #0);
      StartupInfo.cb := SizeOf(StartupInfo);
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      StartupInfo.wShowWindow := SW_HIDE;
      StartupInfo.hStdOutput := hOutputFile;
      StartupInfo.hStdInput := hInputFile;
      Result := CreateProcess(nil, PChar(CommandLine), nil, nil, True,
        CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS, nil, nil, StartupInfo,
        ProcessInfo);
      if Result then
      begin
        WaitForSingleObject(ProcessInfo.hProcess, INFINITE);
        CloseHandle(ProcessInfo.hProcess);
        CloseHandle(ProcessInfo.hThread);
      end;
      CloseHandle(hOutputFile);
    end;
    CloseHandle(hInputFile);
  end;
end;

他のヒント

exeが標準出力に書き込んでいるものをキャプチャしたい場合、

で開始できます 
yourprog.exe > results.txt

これにより、出力がresults.txtに書き込まれます。これを読み取って評価できます。

または、このスレッドで説明されている方法を試すことができます：パイプを作成します生成されたプロセスからの出力を読み取ります。ポスト番号7には、C ++で関連するWinApi関数を使用する方法に関するソースの例があり、Delphiに簡単に変換できます。

実行可能ファイルはどのように文字列を返します？実行可能ファイルが返すことができると私が知っているほとんどは、数字、終了コードです。

共有メモリを使用して、2つのアプリケーション間で通信できます。

Win32 CreateFileMapping関数を使用できます。おそらく、mutexを使用して、メモリマップファイルへの呼び出しを同期できます。

次のコードはファイルを作成します。

var
  fMapping : THandle;
  pMapData : Pointer;

fMapping := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE,
             0, MAPFILESIZE, pchar('MAP NAME GOES HERE'));

PMapData := MapViewOfFile(fMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);

次のコードはマップファイルを閉じます

if PMapData <> nil then
  UnMapViewOfFile(PMapData);
if fMapping <> 0 then
  CloseHandle(fMapping);
ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top