Oracle 9iでCSV文字列を最適に分割する方法
https://stackoverflow.com/questions/1089508
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
Russian質問
Oracle 9i で CSV 文字列を分割できるようにしたい
次の記事を読みましたhttp://www.oappssurd.com/2009/03/string-split-in-oracle.html
しかし、これを機能させる方法がわかりませんでした。これに関する私の質問をいくつか紹介します
- これは Oracle 9i で機能しますか? 機能しない場合は、なぜ機能しないのでしょうか?
- CSV文字列を分割する上記の解決策よりも良い方法はありますか?
- 新しいタイプを作成する必要がありますか?その場合、そのためには特定の権限が必要ですか?
- 関数内で型を宣言できますか?
解決
ここでは、そのページよりも少し簡単ですOracleの文字列トークナイザですが、ないアイデアは、それはのように高速でない場合：
create or replace function splitter_count(str in varchar2, delim in char) return int as
val int;
begin
val := length(replace(str, delim, delim || ' '));
return val - length(str);
end;
create type token_list is varray(100) of varchar2(200);
CREATE or replace function tokenize (str varchar2, delim char) return token_list as
ret token_list;
target int;
i int;
this_delim int;
last_delim int;
BEGIN
ret := token_list();
i := 1;
last_delim := 0;
target := splitter_count(str, delim);
while i <= target
loop
ret.extend();
this_delim := instr(str, delim, 1, i);
ret(i):= substr(str, last_delim + 1, this_delim - last_delim -1);
i := i + 1;
last_delim := this_delim;
end loop;
ret.extend();
ret(i):= substr(str, last_delim + 1);
return ret;
end;
あなたはこのようにそれを使用することができます：
select tokenize('hi you person', ' ') from dual;
VARCHAR(hi,you,person)
他のヒント
ジョイス、
ここでは3例があります：
1）dbms_utility.comma_to_table使用。要素が有効な識別子でなければなりませんので、これは、汎用ルーチンではありません。いくつかの汚い手口で、私たちはそれをより普遍的に動作させることができます：
SQL> declare
2 cn_non_occuring_prefix constant varchar2(4) := 'zzzz';
3 mystring varchar2(2000):='a:sd:dfg:31456:dasd: :sdfsdf'; -- just an example
4 l_tablen binary_integer;
5 l_tab dbms_utility.uncl_array;
6 begin
7 dbms_utility.comma_to_table
8 ( list => cn_non_occuring_prefix || replace(mystring,':',','||cn_non_occuring_prefix)
9 , tablen => l_tablen
10 , tab => l_tab
11 );
12 for i in 1..l_tablen
13 loop
14 dbms_output.put_line(substr(l_tab(i),1+length(cn_non_occuring_prefix)));
15 end loop;
16 end;
17 /
a
sd
dfg
31456
dasd
sdfsdf
PL/SQL-procedure is geslaagd.
2）SQLのレベルで接続を使用します。
：あなたは10グラム以上である場合は、このように、正規表現との組み合わせで、接続ごとのレベルのアプローチを使用することができますSQL> declare
2 mystring varchar2(2000):='a:sd:dfg:31456:dasd: :sdfsdf'; -- just an example
3 begin
4 for r in
5 ( select regexp_substr(mystring,'[^:]+',1,level) element
6 from dual
7 connect by level <= length(regexp_replace(mystring,'[^:]+')) + 1
8 )
9 loop
10 dbms_output.put_line(r.element);
11 end loop;
12 end;
13 /
a
sd
dfg
31456
dasd
sdfsdf
PL/SQL-procedure is geslaagd.
3）再びSQLのを使用すると、レベルによって接続し、しかし、あなたがしているようになりました場合は、古き良きSUBSTR / INSTRとの組み合わせで、あなたは、バージョン9であります：
SQL> declare
2 mystring varchar2(2000):='a:sd:dfg:31456:dasd: :sdfsdf'; -- just an example
3 begin
4 for r in
5 ( select substr
6 ( str
7 , instr(str,':',1,level) + 1
8 , instr(str,':',1,level+1) - instr(str,':',1,level) - 1
9 ) element
10 from (select ':' || mystring || ':' str from dual)
11 connect by level <= length(str) - length(replace(str,':')) - 1
12 )
13 loop
14 dbms_output.put_line(r.element);
15 end loop;
16 end;
17 /
a
sd
dfg
31456
dasd
sdfsdf
PL/SQL-procedure is geslaagd.
あなたはこのブログ投稿では、これらのようないくつかのより多くの技術を見ることができます：<のhref =「http://rwijk.blogspot.com/2007/11/interval-based-row-generation.html」のrel =「noreferrer」 > http://rwijk.blogspot.com/2007/11/interval-based-row-generation.html の
この情報がお役に立てば幸いです。
よろしく、 ロブます。
<時間>あなたのコメントに対処するには：
正規化されたテーブルに区切られた値を挿入する例
まずテーブルを作成します：
SQL> create table csv_table (col)
2 as
3 select 'a,sd,dfg,31456,dasd,,sdfsdf' from dual union all
4 select 'a,bb,ccc,dddd' from dual union all
5 select 'zz,yy,' from dual
6 /
Table created.
SQL> create table normalized_table (value varchar2(10))
2 /
Table created.
、私はここでそれを言及します。しかし、私は確かに行処理であるため、識別子癖の、このバリアントをお勧めして遅いため、行のはありません。
SQL> declare
2 cn_non_occuring_prefix constant varchar2(4) := 'zzzz';
3 l_tablen binary_integer;
4 l_tab dbms_utility.uncl_array;
5 begin
6 for r in (select col from csv_table)
7 loop
8 dbms_utility.comma_to_table
9 ( list => cn_non_occuring_prefix || replace(r.col,',',','||cn_non_occuring_prefix)
10 , tablen => l_tablen
11 , tab => l_tab
12 );
13 forall i in 1..l_tablen
14 insert into normalized_table (value)
15 values (substr(l_tab(i),length(cn_non_occuring_prefix)+1))
16 ;
17 end loop;
18 end;
19 /
PL/SQL procedure successfully completed.
SQL> select * from normalized_table
2 /
VALUE
----------
a
sd
dfg
31456
dasd
sdfsdf
a
bb
ccc
dddd
zz
yy
14 rows selected.
私は、この単一のSQLバリアントをお勧めしません。
SQL> truncate table normalized_table
2 /
Table truncated.
SQL> insert into normalized_table (value)
2 select substr
3 ( col
4 , instr(col,',',1,l) + 1
5 , instr(col,',',1,l+1) - instr(col,',',1,l) - 1
6 )
7 from ( select ',' || col || ',' col from csv_table )
8 , ( select level l from dual connect by level <= 100 )
9 where l <= length(col) - length(replace(col,',')) - 1
10 /
14 rows created.
SQL> select * from normalized_table
2 /
VALUE
----------
a
a
zz
sd
bb
yy
dfg
ccc
31456
dddd
dasd
sdfsdf
14 rows selected.
よろしく、 ロブます。
あなたが何をしたいのビットより明確にすることをお勧めします、我々はあなたに特定の答えを与えることができます。あなたのコードの一部は、常に便利です表示：）
あなたは、CSV数字の文字列を分割するために、偶然にを使用している場合（例えば：1,2,3,4）：/そしてIN文で<のhref = "HTTPSで機能str2tbl()を見ていることを使用します/stackoverflow.com/questions/670922/how-can-i-get-rid-of-dynamic-sql">Question 670922 に。いくつかの変更を使用すると、何が必要VARCHAR2かにそれを変更することができます。
以下では、
:sMyCatagoriesに等しく'1,2,3,4'を設定することができます
create or replace type myTableType as table of number;
create or replace function str2tbl( p_str in varchar2 ) return myTableType
as
l_str long default p_str || ',';
l_n number;
l_data myTableType := myTabletype();
begin
loop
l_n := instr( l_str, ',' );
exit when (nvl(l_n,0) = 0);
l_data.extend;
l_data( l_data.count ) := ltrim(rtrim(substr(l_str,1,l_n-1)));
l_str := substr( l_str, l_n+1 );
end loop;
return l_data;
end;
とselect文でそれを使用して....
SELECT
*
FROM
atable a
WHERE
a.category in (
select * from INLIST (
select cast(str2tbl(:sMyCatagories) as mytableType) from dual
)
);
これは本当にのみ有効です。あなたが一緒にあなたのアプリケーションでSQLをいじるしている場合は、単に声明の中で、通常のを使用します。
SELECT
*
FROM
atable a
WHERE
a.category in (1,2,3,4);
私は最後にこれを使用
create or replace function split
(
p_list varchar2
) return sys.dbms_debug_vc2coll pipelined
is
l_idx pls_integer;
l_list varchar2(32767) := p_list;
l_value varchar2(32767);
begin
loop
l_idx := instr(l_list,',');
if l_idx > 0 then
pipe row(substr(l_list,1,l_idx-1));
l_list := substr(l_list,l_idx+length(','));
else
pipe row(l_list);
exit;
end if;
end loop;
return;
end split;
declare
CURSOR c IS select occurrence_num, graphics from supp where graphics is not null and graphics not like ' %';
begin
FOR r IN c LOOP
insert into image (photo_id,report_id, filename)
select image_key_seq.nextval photo_id, r.occurrence_num report_id,
t.column_value filename from table(split(cast(r.graphics as varchar2(1000)))) t where t.column_value is not null;
END LOOP;
end ;
これは、スキーマ（種類、機能）を追加しないように聞こえます。一つのSQL区切りのテキストを解析する唯一の方法は、INSTRとSUBSTR呼び出しで「夢中」にあります。
DECLARE
V_CSV_STRING VARCHAR2(100);
BEGIN
--Create a test delimited list of first_name, last_name, middle_init
V_CSV_STRING := 'Brian,Hart,M';
select substr( V_CSV_STRING||',', 1, instr(V_CSV_STRING,',')-1 ) FIRST_NAME,
substr( V_CSV_STRING||',,', instr( V_CSV_STRING||',,', ',') +1,
instr( V_CSV_STRING||',,', ',', 1, 2 )-instr(V_CSV_STRING||',,',',')-1 ) LAST_NAME,
rtrim(substr( V_CSV_STRING||',,', instr( V_CSV_STRING||',,',',',1,2)+1),',') MIDDLE_INIT
from dual;
END;
あなたの構造を形式化するために探して、適切なアプリケーションコードの追加の場合（機能、ビュー、種類などを...）私はトム・カイトの<のhref = "http://tkyte.blogspot.com/を見てみましょう2006/06 /変化・イン・lists.html "のrel = "nofollowをnoreferrer">この上の書き込みの<のhref =" http://asktom.oracle.com/pls/asktom/f?p=100 ：11：0 :::: P11_QUESTION_ID：2189860818012" REL = "nofollowをnoreferrer">被験者の
