指定したフォルダーをバックアップするバッチファイルの作成

Question

実は私はこのバッチファイルについてはかなり初心者です。少なくとも基本的なコマンドを知っておくことが重要であることはわかっています。次のことを行うにはどうすればよいですか?

• 指定したフォルダーを圧縮します。
• フォルダーを別の場所に移動します。
• ジップすると、zipファイル名が現在の日付になり、同じ名前の別のzippedファイルがある場合は、20090924-2のように名前を付ける必要があります。

PS: 7-ジップ 私のコンピュータにアーカイブ ソフトウェアとしてインストールされています。

Answer 1

以下にリストされているバッチスクリプトはそれを行います（私はそれをテストし、仕様に合わせて機能します）。zip and moveのディレクトリは、親ディレクトリとディレクトリの名前（最初はparent_foldertozipとfoldertozip）として指定されています。 -directories。）。コピー場所はfoldertargetLocationとして指定され、圧縮ファイルを配置するディレクトリはzipdirとして指定されています。

7-Zip の場所は SEVENZIP_EXE によって設定されます。

また、必要な形式で現在の日付を取得すると、地域設定の短い日付形式に依存することにも注意してください。ISO-8601、中央ヨーロッパ、米国の3つの異なるバージョンをリストしましたリスティングのアクティブなものは米国向けです(「set FDATE=」行)。別のものが必要な場合は、他の2つのいずれかからコピーしてください。

それは、この種のことがはるかに簡単であることに注意すべきだと言った パール, パイソン または パワーシェル.

---

@echo off
@title=Folder zip and move...

rem Parameters
  rem Folder to zip and move
    set PARENT_FOLDERTOZIP=T:\to delete
    set FOLDERTOZIP=Folder to Compress

  rem Target folder for moving the input folder to.
    set FOLDERTARGETLOCATION=s:\move Here

  rem Where to place compressed folders
    set ZIPDIR=D:\toDelete\2009-09-24a


rem Configuration
  set SEVENZIP_EXE=D:\Program Files\7-Zip\7z.exe


rem =================== Date ==============================================
rem There is no universal way inside batch itself to get a
rem date that is independent of regional settings (but is
rem quite trivial if an external program or script
rem (Perl/Python) is available).
rem
rem For short date formats:
rem
rem   -------------------------------------------------------
rem
rem   ISO-8601:
rem     0123456789
rem     yyyy-MM-dd/     E.g.: 2009-09-24
rem
rem     set FDATE=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
rem
rem   -------------------------------------------------------
rem
rem   Central european:
rem     0123456789
rem     dd/MM/yyyy     E.g.: 24/09/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
rem
rem   -------------------------------------------------------
rem
rem   US:
rem
rem     0123456789
rem     MM/dd/yyyy     E.g.: 09/24/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~0,2%%DATE:~3,2%

set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
set ZIPFILE=%ZIPDIR%\%FDATE%.7z

set FOLDERTOZIP_FULLPATH=%PARENT_FOLDERTOZIP%\%FOLDERTOZIP%
mkdir %FOLDERTARGETLOCATION%


rem Does a zip file already exist?
if exist "%ZIPFILE%" GOTO L_ZIPFILE_EXISTS
GOTO L_ZIPFILENAME_OK


rem Find a compressed file that does not already exist.
:L_ZIPFILE_EXISTS
set RNUM=0
:L_TRYANOTHER
set /a RNUM=%RNUM% + 1
set ZIPFILE=%ZIPDIR%\%FDATE%-%RNUM%.7z
echo Candidate: %ZIPFILE% ...
if exist "%ZIPFILE%" GOTO L_TRYANOTHER


rem Zip the folder!
:L_ZIPFILENAME_OK
"%SEVENZIP_EXE%"  a %ZIPFILE%   "%FOLDERTOZIP_FULLPATH%"

if exist "%ZIPFILE%" GOTO L_OKZIP
GOTO L_ERROREND


:L_OKZIP
rem Move folder: copy, then delete source.
set DEST_FOLDER=%FOLDERTARGETLOCATION%\%FOLDERTOZIP%
mkdir "%DEST_FOLDER%"
xcopy /Y /S "%FOLDERTOZIP_FULLPATH%"\*.*   "%DEST_FOLDER%"\
rmdir /S "%FOLDERTOZIP_FULLPATH%"
GOTO L_END


:L_ERROREND
echo 7-Zipping failed !!!


:L_END

pause