Microsoft SQL Server-ストアドプロシージャの作成者

StackOverflow https://stackoverflow.com/questions/608733

質問

SQL Server 2005でストアドプロシージャを作成した人（2008年でも機能する）を確認する良い方法はありますか？ SQL Management Studioでは、プロシージャ上でマウス/プロパティを右クリックして作成日時を取得できますが、作成者を見つけるにはどうすればよいですか？

役に立ちましたか？

解決

今は手遅れかもしれませんが、DDLアクティビティを追跡できます。

管理データベースに、すべてのアクティビティを格納するテーブルがあります。 2005年の新機能であるDDLトリガーを使用します。これらのスクリプトは、admin DB（私にとってはSQL_DBA）にテーブルを作成し、model dbにトリガーを作成し、既存のデータベースにトリガーを作成します。また、最後にsp_msforeachDBステートメントを作成して、それらをすべて無効にしました。

1つの警告-データベースは90の互換モード（各データベースのオプション）である必要があります。そうでない場合、エラーが発生し始める可能性があります。ステートメントのEXECUTE AS部分のアカウントには、管理テーブルに挿入するためのアクセスも必要です。

USE [SQL_DBA]
GO
/****** Object:  Table [dbo].[DDL_Login_Log]    Script Date: 03/03/2009 17:28:10 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE TABLE [dbo].[DDL_Login_Log](
    [DDL_Id] [int] IDENTITY(1,1) NOT NULL,
    [PostTime] [datetime] NOT NULL,
    [DB_User] [nvarchar](100) NULL,
    [DBName] [nvarchar](100) NULL,
    [Event] [nvarchar](100) NULL,
    [TSQL] [nvarchar](2000) NULL,
    [Object] [nvarchar](1000) NULL,
 CONSTRAINT [PK_DDL_Login_Log] PRIMARY KEY CLUSTERED 
(
    [DDL_Id] ASC,
    [PostTime] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY]
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
--This creates the trigger on the model database so all new DBs get it
USE [model]
GO
/****** Object:  DdlTrigger [ddl_DB_User]    Script Date: 03/03/2009 17:26:13 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE TRIGGER [ddl_DB_User] 
ON DATABASE
FOR DDL_DATABASE_SECURITY_EVENTS
AS 

DECLARE @data XML
declare @user nvarchar(100)

SET @data = EVENTDATA()
select @user = convert(nvarchar(100), SYSTEM_USER)

execute as login='domain\sqlagent'
INSERT sql_dba.dbo.DDL_Login_Log 
   (PostTime, DB_User, DBName, Event, TSQL,Object) 
   VALUES 
   (@data.value('(/EVENT_INSTANCE/PostTime)[1]', 'nvarchar(100)'), 
   @user,
    db_name(),
    @data.value('(/EVENT_INSTANCE/EventType)[1]', 'nvarchar(100)'), 
   @data.value('(/EVENT_INSTANCE/TSQLCommand/CommandText)[1]','nvarchar(max)'),
    @data.value('(/EVENT_INSTANCE/ObjectName)[1]', 'nvarchar(1000)')
)

GO
SET ANSI_NULLS OFF
GO
SET QUOTED_IDENTIFIER OFF
GO


--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
--CREATE TRIGGER IN ALL NON SYSTEM DATABASES

DECLARE @dataname varchar(255),
@dataname_header varchar(255),
@command VARCHAR(MAX),
@usecommand VARCHAR(100)
SET @command = '';
DECLARE datanames_cursor CURSOR FOR SELECT name FROM sys.databases 
WHERE name not in ('master', 'pubs', 'tempdb', 'model','msdb')
OPEN datanames_cursor
FETCH NEXT FROM datanames_cursor INTO @dataname
WHILE (@@fetch_status = 0)
BEGIN

PRINT '----------BEGIN---------'

PRINT 'DATANAME variable: ' + @dataname;

EXEC ('USE ' + @dataname);

PRINT 'CURRENT db: ' + db_name();

SELECT @command = 'CREATE TRIGGER DBA_Audit ON DATABASE
FOR DDL_DATABASE_LEVEL_EVENTS
AS
DECLARE @data XML
DECLARE @cmd NVARCHAR(1000)
DECLARE @posttime NVARCHAR(24)
DECLARE @spid NVARCHAR(6)
DECLARE @loginname NVARCHAR(100)
DECLARE @hostname NVARCHAR(100)
SET @data = EVENTDATA()
SET @cmd = @data.value(''(/EVENT_INSTANCE/TSQLCommand/CommandText)[1]'', ''NVARCHAR(1000)'')
SET @cmd = LTRIM(RTRIM(REPLACE(@cmd,'''','''')))
SET @posttime = @data.value(''(/EVENT_INSTANCE/PostTime)[1]'', ''DATETIME'')
SET @spid = @data.value(''(/EVENT_INSTANCE/SPID)[1]'', ''nvarchar(6)'')
SET @loginname = @data.value(''(/EVENT_INSTANCE/LoginName)[1]'',
    ''NVARCHAR(100)'')
SET @hostname = HOST_NAME()
INSERT INTO [DBA_AUDIT].dbo.AuditLog(Command, PostTime,HostName,LoginName)
 VALUES(@cmd, @posttime, @hostname, @loginname);'

 EXEC (@command);
 FETCH NEXT FROM datanames_cursor INTO @dataname;
PRINT '----------END---------'
END
CLOSE datanames_cursor
DEALLOCATE datanames_cursor

--------------------------------------------------------------------------------
--------------------------------------------------------------------------------

----Disable all triggers when things go haywire
sp_msforeachdb @command1='use [?]; IF  EXISTS (SELECT * FROM sys.triggers WHERE name = N''ddl_DB_User'' AND parent_class=0)disable TRIGGER [ddl_DB_User] ON DATABASE'

他のヒント

これはSQL 2005では使用できないと考えています。確かに、SQL Management Studioのプロパティでは使用できず、sys.objectsテーブルやその他の表示されているテーブルでも使用できません。

それがあまりにも前に作成されていない場合は、これを試してください：

DECLARE @path varchar(256)

SELECT @path = path
FROM sys.traces
where id = 1

SELECT *
FROM fn_trace_gettable(@path, 1)

現在の（既定の）デフォルトトレースを選択します。最近作成された（およびサーバーが最近再起動されていない）場合、ストアドプロシージャオブジェクト名とそれを作成したログイン名がトレースデータに含まれます。

Samと同じアイデアに沿って、DDLトリガーを使用して必要な情報をキャプチャし、そのデータをSQLサービスブローカーキューに送信し、管理データベース（必要に応じて別のサーバーにある）に転送できます）これにより、すべてのDDL変更が保持されます。

これにより、DDLトリガーがデータをローカルデータベースのService Brokerキューにロードし、SQLが他のデータベースへのメッセージの移動を処理するため、権限の問題が解消されます。

この方法ではもう少しセットアップが必要になりますが、一度セットアップすると、誰がオブジェクトを変更しても機能します。

この情報をポストポスト（特に数年後）で取得する方法はほとんど不可能です。

ただし、SQL Server Profilerを使用してDDLアクションを追跡できます。 [イベントの選択]で、次のイベントを確認します。

オブジェクト/オブジェクト：変更済み

オブジェクト/オブジェクト：作成

オブジェクト/オブジェクト：削除

カスタマイズオプションも多数あります。出力をファイルまたはテーブルに保存したり、列などに基づいて出力をフィルタリングしたりすることができます。

ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top