ColdFusion 9でデータベースコンテンツのインデックスを作成して検索するためにVerityを使用するにはどうすればよいですか?
-
22-09-2019 - |
質問
ColdFusion 9を使用して、サイトで検索エンジンを構築しようとしました。重要なのは、私が読んだことで、データベースコンテンツでインデックスと検索を行うのに最適なツールです。
しかし、私はこれを行う方法を教えてくれるチュートリアルについて運がないことを運ばずに探し回ります。チュートリアルでさえありません。
MySQL ServerでColdFusion 9を使用しています。これを行う方法を教えていただけますか?または、チュートリアル、記事、または電子書籍も大歓迎です。
解決
実際、CF9用の2つの素晴らしいエンジンがあります。 真性 (クラシック)と solr (モダン)。
どちらものアイデアを実装しています コレクション. 。コレクションの作成と維持は非常に明白であり、手動で見つけることができます(以前のリンクを参照)。
あなたのための主なヒントは見つけることができます cfindex タグマニュアルページ:コレクションにコレクションを入力(更新)できます クエリ データ。タイプを設定します 習慣, 、クエリ名と必要なすべての列を入力します(組み合わせは異なる場合があります)。
その後必要なのは、使用することだけです cfsearch.
また、スケジューラによって実行されたスクリプトをセットアップして、定期的にコレクションを更新することをお勧めします。
編集
サンプルコード(ノート: テストされていないコード、私の古いコンポーネントからの単純化されたカットだけです)。これらはCFCの2つの方法です。
<cffunction name="index" access="public" returntype="any" output="true" hint="Rebuild search index">
<cfargument name="collection" type="string" required="true" hint="Target collection name">
<cfset var local = {} />
<cftry>
<!--- pull the content --->
<cfquery datasource="#variables.dsn#" name="local.getContent">
SELECT C.id, C.title, C.content, P.name AS page
FROM #variables.tableContent# C
INNER JOIN #variables.tablePages# P
ON C.id_page = P.id
</cfquery>
<!--- update collection --->
<cflock name="cfindex_lock" type="exclusive" timeout="30">
<cfindex collection="#arguments.collection#"
action="refresh"
type="custom"
query="local.getContent"
key="id"
custom1="page"
title="title"
body="title,content"
>
</cflock>
<cfreturn true />
<cfcatch type="any">
<!--- custom error handler here --->
<cfreturn false />
</cfcatch>
</cftry>
</cffunction>
<cffunction name="search" access="public" returntype="any" output="true" hint="Perform search through the collection">
<cfargument name="collection" type="string" required="true" hint="Target collection name">
<cfargument name="type" type="string" required="true" hint="Search type">
<cfargument name="criteria" type="string" required="true" hint="Search criteria">
<cfargument name="startrow" type="numeric" required="false" default="1" hint="Select offset">
<cfargument name="maxrows" type="numeric" required="false" default="50" hint="Select items count">
<cfset var local = {} />
<cftry>
<!--- pull the data from collection --->
<cfsearch collection="#arguments.collection#"
name="local.searchResults"
type="#arguments.type#"
criteria="#LCase(arguments.criteria)#"
startrow="#arguments.startrow#"
maxrows="#arguments.maxrows#"
>
<cfset local.resultsArray = [] />
<!--- convert data into the array --->
<cfloop query="local.searchResults">
<cfscript>
local.res = StructNew();
local.res["id"] = local.searchResults.key;
local.res["summary"] = Left(local.searchResults.summary, 500) & "...";
// highlight the search phrase
local.res["summary"] = ReplaceNoCase(local.res["summary"], arguments.criteria, "<strong>" & arguments.criteria & "</strong>", "ALL");
local.res["page"] = local.searchResults.custom1;
local.res["title"] = local.searchResults.title;
ArrayAppend(local.resultsArray, local.res);
</cfscript>
</cfloop>
<cfreturn local.resultsArray />
<cfcatch type="any">
<!--- custom error handler here --->
<cfreturn false />
</cfcatch>
</cftry>
</cffunction>
所属していません StackOverflow