質問
複数のxmlファイルがあり、その名前は別のxmlファイルに保存されています。
xslを使用して、xmlファイルの組み合わせの要約を作成します。 msxml拡張を使用してこれを行う方法があったことを覚えています(msxmlを使用しています)。
select =" document(filename)"
を使用して各ファイルのコンテンツを取得できることは知っていますが、これらすべてのドキュメントを1つに結合する方法がわかりません。
21-Oct-08結合されたxmlでさらに処理したいので、トランスフォームから出力するだけでは不十分です。ノードセットとして変数に保存する必要があります。
解決
これは、できることの簡単な例です。
file1.xml:
<foo>
<bar>Text from file1</bar>
</foo>
file2.xml:
<foo>
<bar>Text from file2</bar>
</foo>
index.xml:
<index>
<filename>file1.xml</filename>
<filename>file2.xml</filename>
summarize.xsl:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:variable name="big-doc-rtf">
<xsl:for-each select="/index/filename">
<xsl:copy-of select="document(.)"/>
</xsl:for-each>
</xsl:variable>
<xsl:variable name="big-doc" select="exsl:node-set($big-doc-rtf)"/>
<xsl:template match="/">
<xsl:element name="summary">
<xsl:apply-templates select="$big-doc/foo"/>
</xsl:element>
</xsl:template>
<xsl:template match="foo">
<xsl:element name="text">
<xsl:value-of select="bar"/>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
index.xml にスタイルシートを適用すると、次のことが得られます。
<?xml version="1.0" encoding="UTF-8"?><summary><text>Text from file1</text><text>Text from file2</text></summary>
トリックは、ドキュメント関数(ほとんどすべてのXSLT 1.0プロセッサでサポートされている拡張機能)を使用してさまざまなドキュメントを読み込み、コンテンツを変数本体の一部として出力し、変数をノードセットに変換してさらに処理することです。処理。
他のヒント
次のようなファイルにファイル名がリストされていると仮定します。
<files>
<file>a.xml</file>
<file>b.xml</file>
</files>
その後、上記のファイルで次のようなスタイルシートを使用できます。
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/">
<root>
<xsl:apply-templates select="files/file"/>
</root>
</xsl:template>
<xsl:template match="file">
<xsl:copy-of select="document(.)"/>
</xsl:template>
</xsl:stylesheet>
document()
を使用して、変換プロセス中にさらにXMLドキュメントをロードできます。それらはノードセットとしてロードされます。つまり、最初にファイル名を含むXMLをフィードしてXSLTにロードし、そこから取得します。
<xsl:copy-of select="document(@href)/"/>
すべての回答に感謝します。 msxmlで使用しているソリューションの基本は次のとおりです。
<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ms="urn:schemas-microsoft-com:xslt">
<xsl:output method="xml"/>
<xsl:template match="/">
<xsl:variable name="combined">
<xsl:apply-templates select="files"/>
</xsl:variable>
<xsl:copy-of select="ms:node-set($combined)"/>
</xsl:template>
<xsl:template match="files">
<multifile>
<xsl:apply-templates select="file"/>
</multifile>
</xsl:template>
<xsl:template match="file">
<xsl:copy-of select="document(@name)"/>
</xsl:template>
</xsl:stylesheet>
各ファイルは約8 MBであり、変換に非常に長い時間がかかるため、パフォーマンスを改善しようとしていますが、それは別の質問です。