Tcl / Tkの例？

Question

Tcl / Tk は、小さなGUIを簡単にスクリプト化する方法です。

ボタンとテキストウィジェットを使用して、誰でも良い例を挙げることができます。ボタンが押されると、シェルコマンドが実行され、出力が text ウィジェットにパイプされます。

有用なタスクのその他のわかりやすい例がある場合は、それらも追加してください。

Answer 1

これは、fileeventsを使用したより完全な例です。これは常に自動スクロールします。使いやすさのために、おそらくテキストの下部が表示されている場合（つまり、ユーザーがスクロールバーを動かしていない場合）にのみ自動スクロールしたいでしょうが、読者がこの長い例を維持するための演習として残しておきますもう取得できません。

package require Tk

proc main {} {
    if {[lsearch -exact [font names] TkDefaultFont] == -1} {
        # older versions of Tk don't define this font, so pick something
        # suitable
        font create TkDefaultFont -family Helvetica -size 12
    }
    # in 8.5 we can use {*} but this will work in earlier versions
    eval font create TkBoldFont [font actual TkDefaultFont] -weight bold

    buildUI
}

proc buildUI {} {
    frame .toolbar
    scrollbar .vsb -command [list .t yview]
    text .t \
        -width 80 -height 20 \
        -yscrollcommand [list .vsb set] \
        -highlightthickness 0
    .t tag configure command -font TkBoldFont
    .t tag configure error   -font TkDefaultFont -foreground firebrick
    .t tag configure output  -font TkDefaultFont -foreground black

    grid .toolbar -sticky nsew
    grid .t .vsb  -sticky nsew
    grid rowconfigure . 1 -weight 1
    grid columnconfigure . 0 -weight 1

    set i 0
    foreach {label command} {
        date     {date} 
        uptime   {uptime} 
        ls       {ls -l}
    } {
        button .b$i -text $label -command [list runCommand $command]
        pack .b$i -in .toolbar -side left
        incr i
    }
}

proc output {type text} {
    .t configure -state normal
    .t insert end $text $type "\n"
    .t see end
    .t configure -state disabled
}

proc runCommand {cmd} {
    output command $cmd
    set f [open "| $cmd" r]
    fconfigure $f -blocking false
    fileevent $f readable  [list handleFileEvent $f]
}

proc closePipe {f} {
    # turn blocking on so we can catch any errors
    fconfigure $f -blocking true
    if {[catch {close $f} err]} {
        output error $err
    }
}

proc handleFileEvent {f} {
    set status [catch { gets $f line } result]
    if { $status != 0 } {
        # unexpected error
        output error $result
        closePipe $f

    } elseif { $result >= 0 } {
        # we got some output
        output normal $line

    } elseif { [eof $f] } {
        # End of file
        closePipe $f

    } elseif { [fblocked $f] } {
        # Read blocked, so do nothing
    }
}


main

Answer 2

いくつかの提案：

99strong行を指定する代わりに、出力を text ウィジェットに追加するには、インデックス end を使用できます。これは、最後の改行の直後の位置を参照します。たとえば、

.main insert end "$x\n"

コマンドの出力中にテキストをスクロールするには、 see コマンドを使用します。たとえば、.mainテキストウィジェットに追加した後

.main see end

fileevent コマンドを使用して、コマンド出力を非同期で取得することを検討することもできます。

Answer 3

始めましょう...改善を提案してください。つまり、コマンドの出力中にスクロールしたい

#!/usr/bin/wish

proc push_button {} {
    put_text
    .main see end
}

proc put_text {} {
  set f [ open "| date" r]
  while {[gets $f x] >= 0} {
    .main insert end "$x\n"    
  }
  catch {close $f}
}

button .but -text "Push Me" -command "push_button"
text .main -relief sunken -bd 2 -yscrollcommand ".scroll set"
scrollbar .scroll -command ".main yview"

pack .but
pack .main -side left -fill y
pack .scroll -side right -fill y

Answer 4

wiki.tcl.tk は、あらゆる種類の例