exemplos Tcl / Tk?

Question

Tcl / Tk é uma maneira simples de scripts pequenos GUIs.

Alguém pode dar um exemplo agradável com um botão e texto widget. Quando o botão é pressionado deve um comando ser executado ea saída canalizada para o texto Widget.

Se você tem outros exemplos agradáveis ??e limpos para tarefas úteis, por favor, adicioná-los também.

Answer 1

Aqui está um exemplo mais completo usando fileevents. Esta vontade auto-percorrer todo o tempo. Para fins de usabilidade você provavelmente só quer auto-scroll se o fundo do texto é visível (ou seja: se o usuário não se moveu a barra de rolagem), mas vou deixar isso como um exercício para o leitor a manter esta já longa exemplo de ficar por mais tempo.

package require Tk

proc main {} {
    if {[lsearch -exact [font names] TkDefaultFont] == -1} {
        # older versions of Tk don't define this font, so pick something
        # suitable
        font create TkDefaultFont -family Helvetica -size 12
    }
    # in 8.5 we can use {*} but this will work in earlier versions
    eval font create TkBoldFont [font actual TkDefaultFont] -weight bold

    buildUI
}

proc buildUI {} {
    frame .toolbar
    scrollbar .vsb -command [list .t yview]
    text .t \
        -width 80 -height 20 \
        -yscrollcommand [list .vsb set] \
        -highlightthickness 0
    .t tag configure command -font TkBoldFont
    .t tag configure error   -font TkDefaultFont -foreground firebrick
    .t tag configure output  -font TkDefaultFont -foreground black

    grid .toolbar -sticky nsew
    grid .t .vsb  -sticky nsew
    grid rowconfigure . 1 -weight 1
    grid columnconfigure . 0 -weight 1

    set i 0
    foreach {label command} {
        date     {date} 
        uptime   {uptime} 
        ls       {ls -l}
    } {
        button .b$i -text $label -command [list runCommand $command]
        pack .b$i -in .toolbar -side left
        incr i
    }
}

proc output {type text} {
    .t configure -state normal
    .t insert end $text $type "\n"
    .t see end
    .t configure -state disabled
}

proc runCommand {cmd} {
    output command $cmd
    set f [open "| $cmd" r]
    fconfigure $f -blocking false
    fileevent $f readable  [list handleFileEvent $f]
}

proc closePipe {f} {
    # turn blocking on so we can catch any errors
    fconfigure $f -blocking true
    if {[catch {close $f} err]} {
        output error $err
    }
}

proc handleFileEvent {f} {
    set status [catch { gets $f line } result]
    if { $status != 0 } {
        # unexpected error
        output error $result
        closePipe $f

    } elseif { $result >= 0 } {
        # we got some output
        output normal $line

    } elseif { [eof $f] } {
        # End of file
        closePipe $f

    } elseif { [fblocked $f] } {
        # Read blocked, so do nothing
    }
}


main

Answer 2

Algumas sugestões:

Para anexar a saída para o texto widget, em vez de especificar linha 999999, você pode usar o índice final , que se refere à posição logo após a última mudança de linha. Por exemplo,

.main insert end "$x\n"

Para ter a rolagem de texto que o comando está a emitir, use o comando ver. Por exemplo, depois de acrescentar ao texto .main Widget

.main see end

Você também pode querer considerar pegar a saída do comando de forma assíncrona, utilizando o fileevent comando.

Answer 3

Eu posso dar um começo ... por favor sugerir melhorias. Ou seja eu gostaria que a rolagem como o comando é saída

#!/usr/bin/wish

proc push_button {} {
    put_text
    .main see end
}

proc put_text {} {
  set f [ open "| date" r]
  while {[gets $f x] >= 0} {
    .main insert end "$x\n"    
  }
  catch {close $f}
}

button .but -text "Push Me" -command "push_button"
text .main -relief sunken -bd 2 -yscrollcommand ".scroll set"
scrollbar .scroll -command ".main yview"

pack .but
pack .main -side left -fill y
pack .scroll -side right -fill y

Answer 4

wiki.tcl.tk é bom site para todos os tipos de exemplos