Nekoとhaxe.Timer.delayed（）

Question

すべてのHaxe開発者が知っているように、 haxe.Timer.delayed（）を使用して、関数呼び出しをしばらく遅らせることができます。ただし、この機能はNekoにはまったく存在しません。同じ結果を達成する方法はありますか？

Answer 1

最初に確認する必要がありますが、

function delayed(f, time) {
   neko.vm.Thread.create(function() {
       neko.Sys.sleep(time);
       f();
   });
}

可能な限り最も近いものである可能性があります。唯一の欠点は、アプリケーションがマルチスレッドになり、深刻な問題が発生する可能性があることです。

Answer 2

私はあなたの問題について考えました、そして、最善の方法はNekoのためにあなた自身のTimerクラスを作成することだと思います。タイマークラスを作成しました：

NekoTimer.hx

package;
import neko.Sys;

    class NekoTimer 
    {
    private static var threadActive:Bool = false;
    private static var timersList:Array<TimerInfo> = new Array<TimerInfo>();
    private static var timerInterval:Float = 0.1;

    public static function addTimer(interval:Int, callMethod:Void->Void):Int
    {
        //setup timer thread if not yet active
        if (!threadActive) setupTimerThread();

        //add the given timer
        return timersList.push(new TimerInfo(interval, callMethod, Sys.time() * 1000)) - 1;
    }

    public static function delTimer(id:Int):Void
    {
        timersList.splice(id, 1);
    }

    private static function setupTimerThread():Void
    {
        threadActive = true;
        neko.vm.Thread.create(function() {
            while (true) {
                Sys.sleep(timerInterval);
                for (timer in timersList) {
                    if (Sys.time() * 1000 - timer.lastCallTimestamp >= timer.interval) {
                        timer.callMethod();
                        timer.lastCallTimestamp = Sys.time() * 1000;
                    }
                }
            }
        });
    }
}

private class TimerInfo
{
    public var interval:Int;
    public var callMethod:Void->Void;
    public var lastCallTimestamp:Float;

    public function new(interval:Int, callMethod:Void->Void, lastCallTimestamp:Float) {
        this.interval = interval;
        this.callMethod = callMethod;
        this.lastCallTimestamp = lastCallTimestamp;
    }
}

次のように呼び出します：

package ;

import neko.Lib;

class Main 
{
    private var timerId:Int;

    public function new()
    {
        trace("setting up timer...");
        timerId = NekoTimer.addTimer(5000, timerCallback);
        trace(timerId);

        //idle main app
        while (true) { }
    }

    private function timerCallback():Void
    {
        trace("it's now 5 seconds later");
        NekoTimer.delTimer(timerId);
        trace("removed timer");
    }

    //neko constructor
    static function main() 
    {
        new Main();
    }
}

役立つこと。

注：これの精度は100msです。 timerInterval設定を減らすことでこれを増やすことができます。

Answer 3

クラスも使用しましたが、1つの問題が見つかりました。完全にリアルタイムではないため、インターバルをスリープし、関数を呼び出し、インターバルを再度スリープします。そのため、実行している関数の所要時間に応じて、速度が遅くなったり速くなったりします。

次のように39行目を置き換えて解決しました：

//timer.lastCallTimestamp = Sys.time() * 1000;
timer.lastCallTimestamp = timer.lastCallTimestamp + timer.interval;

Answer 4

はい、最初の回答で言及したこと以外は何も知りません。 LinuxではSIGALARMを使用できますが、これは些細な100％純粋なCコードではなく、VMのクラッシュを避けるために細心の注意を払って処理する必要があります。