.hおよび.cppファイルを生成するレイジーC ++ .lzzファイルをプリプロセスするためにCmakeのビルドルールを作成するにはどうすればよいですか?
質問
私がやりたいのは、怠zyなC ++ .lzzファイルを書いてから、ビルドの前にLZZを実行して、最終アプリケーションに組み込まれる.cppおよび.hファイルを生成することです。
これを行う方法はありますか?
解決
これがこれを行う方法の例です...最初にあなたは lzz
プログラム、その使用のため find_program
指図:
find_program(LZZ_COMMAND lzz)
これは設定されます LZZ_COMMAND
コンパイラのパスへ。次に、CMAKEカスタムコマンドを使用して、LZZファイルをC ++ヘッダー/実装ファイルにコンパイルします。
add_custom_command(
OUTPUT ${output}
COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
これにより、現在のビルドディレクトリ内のファイルが生成されます。また、出力が生成されたファイルであることを指定する必要があります。
set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
それをすべてまとめると、cmakelists.txtファイルを取得します。
cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
get_filename_component(base ${filename} NAME_WE)
set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
set(output ${base_abs}.cpp ${base_abs}.h)
add_custom_command(
OUTPUT ${output}
COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)
おそらく、最終的にLZZにパスやその他のオプションを含めることもできます。すべての怠zyなC ++スタッフをモジュールファイルに配置し、cmakelists.txtからそれを含めた場合、それは少しきれいになります。しかし、これは基本的なアイデアです。
他のヒント
richqのスクリプトに基づいたcmakelists.txtを共有したかっただけです。 *.cppおよび *.hppファイルは、 *.lzzファイルに適切に依存するようになりました。 *.lzzファイルはプロジェクトに追加されます(上記のAbsenseの質問に応答します)が、source_groupコマンドを使用して生成されたファイルとは別に保持されます。
私にとって唯一の残りの取引屋は、 *.lzzファイルの現在のファイルをコンパイルできないことです。
cmake_minimum_required(VERSION 2.8)
PROJECT(LzzTest)
find_program(LZZ_COMMAND lzz.exe)
# Syntax:
# add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated
# files are added to the <output> list. The files are generated in the binary dir.
#
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
# Only process *.lzz files
get_filename_component(ext ${filename} EXT)
if(NOT ext STREQUAL ".lzz")
return()
endif()
set(header_extension "hpp")
get_filename_component(base ${filename} NAME_WE)
set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
set(${output} ${${output}} ${outfiles} PARENT_SCOPE)
#message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
add_custom_command(
OUTPUT ${outfiles}
COMMAND ${LZZ_COMMAND}
-o ${CMAKE_CURRENT_BINARY_DIR} # output dir
-hx ${header_extension}
-sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
-sd -hd -id -td -nd # don't output files that didn't change
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
)
set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()
include_directories(${CMAKE_CURRENT_BINARY_DIR})
set(SOURCES
A.lzz
B.lzz
main.cpp
)
foreach(file ${SOURCES})
add_lzz_file(GENERATED_SOURCES ${file})
endforeach()
source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})
add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})
メーカーのために:
sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz
sourcecode.h、sourcecode.cpp、およびlazy-cppに正しい値を入力します。私はそれらを知りません。