Как сделать правила сборки в Cmake, чтобы предварительно обработать ленивые файлы c ++ .lzz, которые генерируют файлы .h и .cpp?

Question

Что я хотел бы сделать, так это написать просто ленивые файлы c ++ .lzz, а затем пропустить Lzz перед сборкой для создания файлов .cpp и .h, которые будут встроены в окончательное приложение, вроде как MOC работает с QT.

Есть какой-либо способ сделать это?

Answer 1

Вот пример того, как это сделать ... сначала вам нужно найти lzz программа для этого используйте find_program Команда:

find_program(LZZ_COMMAND lzz)

Это устанавливает LZZ_COMMAND к пути компилятора. Затем используйте пользовательскую команду Cmake для составления файла LZZ в файлы заголовка C ++/реализации:

add_custom_command(
    OUTPUT ${output}
    COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})

Это генерирует файлы в текущем каталоге сборки, на случай, если вы делаете строительные сборки. Вам также необходимо указать, что выходы являются сгенерированными файлами:

set_source_files_properties(${output} PROPERTIES GENERATED TRUE)

Составьте все это вместе, и вы получите файл cmakelists.txt.

cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
    get_filename_component(base ${filename} NAME_WE)
    set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
    set(output ${base_abs}.cpp ${base_abs}.h)
    add_custom_command(
        OUTPUT ${output}
        COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)

Вы, вероятно, также захотите добавить, включите Path и другие варианты для Lzz в конце концов. Если вы поместите все ленивые материалы C ++ в файл модуля и включили в себя, что из cmakelists.txt это было бы немного чище. Но это основная идея.

Answer 2

Я просто хотел поделиться своим cmakelists.txt, который основан на сценарии Рича. Файлы *.cpp и *.hpp теперь правильно зависят от файлов *.lzz. Файлы.

Единственным оставшимся для меня является неспособность составить текущий файл для *.lzz Files.

cmake_minimum_required(VERSION 2.8)

PROJECT(LzzTest)

find_program(LZZ_COMMAND lzz.exe)

# Syntax: 
#   add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated 
# files are added to the <output> list. The files are generated in the binary dir.
# 
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
  # Only process *.lzz files
  get_filename_component(ext ${filename} EXT)
  if(NOT ext STREQUAL ".lzz")
    return()
  endif()

  set(header_extension "hpp")
  get_filename_component(base ${filename} NAME_WE)
  set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
  set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
  set(${output} ${${output}} ${outfiles} PARENT_SCOPE)

  #message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
  add_custom_command(
    OUTPUT ${outfiles}
    COMMAND ${LZZ_COMMAND} 
      -o ${CMAKE_CURRENT_BINARY_DIR} # output dir
      -hx ${header_extension}
      -sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
      -sd -hd -id -td -nd # don't output files that didn't change
      ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
  )

  set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()

include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
  A.lzz
  B.lzz
  main.cpp
)

foreach(file ${SOURCES})
  add_lzz_file(GENERATED_SOURCES ${file})
endforeach()

source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})

add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})

Answer 3

Для Make:

sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz

Заполните sourcecode.h, sourcecode.cpp и lazy-cpp с правильными значениями. Я их не знаю.