エルランのmochijson2でJSONをデコードします

Question

私はいくつかのJSONデータを持っているVARを持っています：

A = <<"{\"job\": {\"id\": \"1\"}}">>. 

mochijson2を使用して、データをデコードします。

 Struct = mochijson2:decode(A). 

そして今、私はこれを持っています：

{struct,[{<<"job">>,{struct,[{<<"id">>,<<"1">>}]}}]}

（たとえば）、「ジョブ」または「ID」を読み込もうとしています。

struct.get_valueを使用してみましたが、機能していないようです。

何か案は？

Answer 1

データは{struct、proplist（）}形式であるため、ここにあなたがすることは次のとおりです。

{struct, JsonData} = Struct,
{struct, Job} = proplists:get_value(<<"job">>, JsonData),
Id = proplists:get_value(<<"id">>, Job),

Proplistsの詳細については、以下をご覧ください。 http://www.erlang.org/doc/man/proplists.html

Answer 2

JSON構造にアクセスする別のヘルパー関数：

jsonobj({struct,List}) ->
    fun({contains,Key}) ->
        lists:keymember(Key,1,List);
    ({raw,Key}) ->
        {_,Ret} = lists:keyfind(Key,1,List),Ret;
    (Key) ->
        {_,Ret} = lists:keyfind(Key,1,List),
        jsonobj(Ret)
    end;
jsonobj(List) when is_list(List) ->
    fun(len) ->
        length(List);
    (Index) ->
        jsonobj(lists:nth(Index,List))
    end;
jsonobj(Obj) -> Obj.

使用法：

1> A=mochijson2:decode(<<"{\"job\": {\"id\": \"1\", \"ids\": [4,5,6], \"isok\": true}}">>).
2> B=jsonobj(A).
3> B(<<"job">>).
#Fun<jsonutils.1.33002110>
4> (B(<<"job">>))(<<"id">>).
1
5> (B(<<"job">>))(<<"ids">>).
#Fun<jsonutils.1.9495087>
6> (B(<<"job">>))({raw,<<"ids">>}).
[4,5,6]
7> ((B(<<"job">>))(<<"ids">>))(1).
4
8> B({raw,<<"job">>}).
{struct,[{<<"id">>,<<"1">>},
               {<<"ids">>,[1,2,3]},
               {<<"isok">>,true}]}
9> B({contains,<<"job">>}).
true
10> B({contains,<<"something">>}).
false
11> ((B(<<"job">>))(<<"ids">>))(len)
3

JSONから値を抽出することはより簡単にはないと思います。

Answer 3

データにアクセスする別の方法を次に示します。使用します 記録構文 使いやすさ。

-record(struct, {lst=[]}).

A = <<"{\"job\": {\"id\": \"1\"}}">>,
Struct = mochijson2:decode(A), 
Job = proplists:get_value(<<"job">>, Struct#struct.lst),
Id = proplists:get_value(<<"id">>, Job#struct.lst),

代わりにレコードを使用して回答とまったく同じことをします。 mochijson2を使用する場合の別のオプション。私は個人的にこの構文が好きです。

Answer 4

以前に与えられた答えに加えてもいいこともあります チュートリアル Mochiweb、Json（ビデオ）。

Answer 5

私のお気に入りのMochijsonデータのヘンディング方法は、すべての構造体をハッシュマップに置き換えることであり、その後、それらがきれいに一致することができます。そうするために、私はこの理解しやすい機能を書きました：

structs_to_maps({struct, Props}) when is_list(Props) ->
    lists:foldl(
        fun({Key, Val}, Map) ->
            Map#{Key => structs_to_maps(Val)}
        end,
        #{},
        Props
    );
structs_to_maps(Vals) when is_list(Vals) ->
    lists:map(
        fun(Val) ->
            structs_to_maps(Val)
        end,
        Vals
    );
structs_to_maps(Val) ->
    Val.

これがそれを使用する方法の例です：

do() ->
    A = <<"{\"job\": {\"id\": \"1\"}}">>,
    Data = structs_to_maps(mochijson2:decode(A)),
    #{<<"job">> := #{<<"id">> := Id}} = Data,
    Id.

これには、特に予期しない形状を受ける可能性のある着信データを操作する場合に多くの利点があります。