Декодирует json с mochijson2 в Эрланге

Question

У меня есть VAR, у которых есть некоторые данные JSON:

A = <<"{\"job\": {\"id\": \"1\"}}">>. 

Используя Mochijson2, я декодирую данные:

 Struct = mochijson2:decode(A). 

И теперь у меня есть это:

{struct,[{<<"job">>,{struct,[{<<"id">>,<<"1">>}]}}]}

Я пытаюсь прочитать (например), «Работа» или «ID».

Я пытался использовать struct.get_value, но это не работает.

Любые идеи?

Answer 1

Данные в формате {struct, proplist ()}, поэтому вот что вы делаете:

{struct, JsonData} = Struct,
{struct, Job} = proplists:get_value(<<"job">>, JsonData),
Id = proplists:get_value(<<"id">>, Job),

Вы можете прочитать больше о прослушивах по адресу: http://www.erlang.org/doc/man/proplists.html.

Answer 2

Другой помощник функции для доступа к структуре JSON:

jsonobj({struct,List}) ->
    fun({contains,Key}) ->
        lists:keymember(Key,1,List);
    ({raw,Key}) ->
        {_,Ret} = lists:keyfind(Key,1,List),Ret;
    (Key) ->
        {_,Ret} = lists:keyfind(Key,1,List),
        jsonobj(Ret)
    end;
jsonobj(List) when is_list(List) ->
    fun(len) ->
        length(List);
    (Index) ->
        jsonobj(lists:nth(Index,List))
    end;
jsonobj(Obj) -> Obj.

Использование:

1> A=mochijson2:decode(<<"{\"job\": {\"id\": \"1\", \"ids\": [4,5,6], \"isok\": true}}">>).
2> B=jsonobj(A).
3> B(<<"job">>).
#Fun<jsonutils.1.33002110>
4> (B(<<"job">>))(<<"id">>).
1
5> (B(<<"job">>))(<<"ids">>).
#Fun<jsonutils.1.9495087>
6> (B(<<"job">>))({raw,<<"ids">>}).
[4,5,6]
7> ((B(<<"job">>))(<<"ids">>))(1).
4
8> B({raw,<<"job">>}).
{struct,[{<<"id">>,<<"1">>},
               {<<"ids">>,[1,2,3]},
               {<<"isok">>,true}]}
9> B({contains,<<"job">>}).
true
10> B({contains,<<"something">>}).
false
11> ((B(<<"job">>))(<<"ids">>))(len)
3

Я не думаю, что извлечение ценностей от JSON может быть упрощенным.

Answer 3

Вот еще один способ доступа к данным. Использует Записывает синтаксис Для простоты использования.

-record(struct, {lst=[]}).

A = <<"{\"job\": {\"id\": \"1\"}}">>,
Struct = mochijson2:decode(A), 
Job = proplists:get_value(<<"job">>, Struct#struct.lst),
Id = proplists:get_value(<<"id">>, Job#struct.lst),

Делает именно то же самое, что и ответ, использующий записи. Просто еще один вариант при использовании mochijson2. Я лично люблю этот синтаксис лучше.

Answer 4

Добавление к ответу, указанному ранее, есть также хороший руководство На Mochiweb Json (видео).

Answer 5

Мой любимый способ Handledening Data Mochijson Data заменяет все структуры с помощью хеш-карт, после чего они могут быть чисто узор. Для этого я написал это легко понять функцию:

structs_to_maps({struct, Props}) when is_list(Props) ->
    lists:foldl(
        fun({Key, Val}, Map) ->
            Map#{Key => structs_to_maps(Val)}
        end,
        #{},
        Props
    );
structs_to_maps(Vals) when is_list(Vals) ->
    lists:map(
        fun(Val) ->
            structs_to_maps(Val)
        end,
        Vals
    );
structs_to_maps(Val) ->
    Val.

Вот пример того, как его использовать:

do() ->
    A = <<"{\"job\": {\"id\": \"1\"}}">>,
    Data = structs_to_maps(mochijson2:decode(A)),
    #{<<"job">> := #{<<"id">> := Id}} = Data,
    Id.

Это имеет много преимуществ, особенно при работе с входящими данными, которые могут иметь неожиданную форму.