.Net ManagementBaseObjectをManagementObjectに変換

Question

次のコードを使用して、コンピューターで開始されたすべてのプロセスを書き込もうとしています。私の問題は、EventArrivedメソッドに、ManagementBaseObject型のNewEventプロパティを持つEventArrivedEventArgsが渡されることです。これには、InvokeMethodメソッドはありません。 NewEventプロパティを何らかの方法でManagementObjectに変換できますか、またはManagementObjectを再クエリして作成する必要がありますか？以下のコードは問題なく動作しますが、再クエリを行いたくないです。

Imports System.Management

Public NotInheritable Class EntryPoint

    Public Shared Sub Main(ByVal args() As String)

        Dim scope As New ManagementScope("\\.\root\cimV2")
        Dim query As New WqlEventQuery("__InstanceCreationEvent", TimeSpan.FromSeconds(1), "TargetInstance isa ""Win32_Process""")

        Using watcher As New ManagementEventWatcher(scope, query)
            AddHandler watcher.EventArrived, AddressOf EventArrived
            watcher.Start()
            Console.WriteLine("Waiting for processes to start...")
            Console.ReadLine()
            watcher.Stop()
        End Using

    End Sub

    Private Shared Sub EventArrived(ByVal sender As Object, ByVal e As EventArrivedEventArgs)

        Dim targetInstance As ManagementBaseObject = e.NewEvent("TargetInstance")
        Dim process As New ManagementObject("win32_process.handle=" + targetInstance("ProcessId").ToString())
        Dim output(1) As String
        process.InvokeMethod("GetOwner", output)
        Console.WriteLine("Process {0} started by {2}\{1}", targetInstance("Name"), output(0), output(1))

    End Sub

End Class

Answer 1

IS オブジェクトは ManagementObject インスタンスですか？インデクサーは、汎用プロパティであるため、戻り値を Base として渡す場合があります。これを試してください：

Private Shared Sub EventArrived(ByVal sender As Object, ByVal e As EventArrivedEventArgs)
    Dim targetInstance As ManagementBaseObject = e.NewEvent("TargetInstance")

    If TypeOf targetInstance Is ManagementObject Then
        Dim mo as ManagementObject = DirectCast(targetInstance, ManagementObject)
        Dim output(1) as String

        mo.InvokeMethod("GetOwner", output)

        Console.WriteLine("Process {0} started by {2}\{1}", targetInstance("Name"), output(0), output(1))
    End If
End Sub