他のHTMLページから抽出されたDIVからHTMLページを構築するスクリプト

StackOverflow https://stackoverflow.com/questions/1211718

  •  06-07-2019
  •  | 
  •  

質問

HTMLレポートのセットがあり、各レポートには特定のIDを持つ2つのDIV要素が含まれており、全体の要約レポート（ここでもHTMLファイル）にまとめる必要があります。

私の最初の考えは、これはPerlスクリプトの理想的な仕事であるということですが、最新の社内Perlスキルはありません（.NET C＃ショップです）。

推奨されるアプローチに関する考えや提案を歓迎します...

役に立ちましたか？

解決

適切なHTMLパーサーを使用します。 Perlには HTML :: Parser があり、C＃には次のものがいくつかあると確信しています。まあ。

他のヒント

Perlを使用して、 HTML :: TokeParser および HTML :: Template が役立ちます。以下に簡単な例を示します。

#!/usr/bin/perl

use strict;
use warnings;

use HTML::TokeParser;
use HTML::Template;

use Data::Dumper;

my ($html_file) = @ARGV;

open my $html_handle, '<:utf8', $html_file
    or die "Cannot open '$html_file': $!";

my $parser = HTML::TokeParser->new( $html_handle );

my @divs;

while ( my $tag = $parser->get_tag('div') ) {
    my $attr = $tag->[1];
    next unless ref $attr eq 'HASH';
    next unless defined( my $id = $attr->{id} );
    next unless $id eq 'div1' or $id eq 'div2';

    my $div = $tag->[-1];
    my $in_wanted = 1;

    while ( $in_wanted ) {
        my $token = $parser->get_token;
        if ( $token->[0] eq 'T' ) {
            $div .= $token->[1];
        }
        else {
            $div .= $token->[-1];
        }
        my ($type, $name) = @$token[0, 1];
        if ( $name eq 'div' ) {
            $in_wanted += $type eq 'S' ?  1
                        : $type eq 'E' ? -1
                        : 0;
            next;
        }
        if ( $type eq 'E' and $name eq 'html' ) {
            warn "Warning: Reached the end of '$html_file'\n";
            last;
        }
    }

    push @divs, {DIV => $div};
}

print output( @divs );

sub output {
    my $tmpl_html = <<EO_TMPL;
<html>
<body>
<TMPL_LOOP DIVS>
    <TMPL_VAR DIV>
</TMPL_LOOP>
</body>
</html>
EO_TMPL
    my $tmpl = HTML::Template->new(
        scalarref => \$tmpl_html,
    );
    $tmpl->param( DIVS => \@_ );
    return $tmpl->output;
}

divにネストされたdivが含まれる場合、直接的な正規表現十分ではない可能性があります。これは、終了div要素にIDが含まれていないため、正規表現が終了タグと一致するのが難しいためです。

divが次の場合：

<div id="findme">
    <!-- No other divs here! -->
</div>

その後、正規表現を使用することができます（欲張りに注意してください）、これのよりエレガントなバージョン：

<div id="findme">(.*?)</div>

注：正規表現が実行されないことはかなり確かです。しばらく前です！

HTMLパーサーライブラリを使用して構造を解析し、divの内部の文字オフセットを取得してから、その範囲をバッファーから取得します。 HTMLライブラリを使用すると、解析して目的のdivが終了する場所を見つけることができます。

このチュートリアル役に立つかもしれません。これらのパーサーを使用すると、おそらくdivなどのタグで囲まれたデータを正確に抽出できます。

C＃HTMLパーサーを使用することもできます、それらはすべて同様の仕事をします。ドキュメントを見て、ツリーを構築しないことを確認し、囲まれたdivデータの文字オフセットを取得できるようにします（抽出できるようにする）。そのデータ。

ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top