pl / sql forループで「次」と言う別の方法はありますか？

StackOverflow https://stackoverflow.com/questions/429508

質問

したがって、IDのリストを処理するforループがあり、かなり複雑なことがいくつかあります。すべてのい詳細に進むことなく、基本的にこれ：

    DECLARE
      l_selected APEX_APPLICATION_GLOBAL.VC_ARR2;

      ...snip...
    BEGIN

      -- get the list ids
      l_selected := APEX_UTIL.STRING_TO_TABLE(:P4_SELECT_LIST);
      -- process each in a nice loop
      FOR i IN 1..l_selected.count 
      LOOP
        -- do some data checking stuff...

        -- here we will look for duplicate entries, so we can noop if duplicate is found
        BEGIN
          SELECT county_id INTO v_dup_check FROM org_county_accountable
          WHERE organization_id = :P4_ID AND county_id = v_county_id;
          -- NEXT;! NOOP;! but there is no next!
        EXCEPTION WHEN NO_DATA_FOUND THEN
          dbms_output.put_line('no dups found, proceeding');
        END;
        -- here we have code we only want to execute if there are no dupes already
        IF v_dup_check IS NULL THEN
          -- if not a duplicate record, proceed...

        ELSE
          -- reset duplicate check variable
          v_dup_check := NULL;
        END;
      END LOOP;
    END;

通常これを処理する方法は、値を選択し、IFステートメントチェックで次のコードをラップして、重複するチェック変数がNULLであることを確認することです。しかし、それは迷惑です。 NEXTと言いたいだけです。またはNOOP;か何か。特に、すでにNO_DATA_FOUND例外をキャッチする必要があるためです。 Oracleに手紙を書くことができると思いますが、他の人がどのようにこれを処理するのか興味があります。

私もこれを関数でラップすることもできますが、少しきれいでシンプルなものを探していました。

役に立ちましたか？

解決

行数をカウントすることも可能ですが（Pourquoi Litytestdataを参照）、 when_no_data_found exception ブロックで必要な操作を実行することもできます。

declare 
  l_selected    apex_application_global.vc_arr2;
  l_county_id   org_county_accountable.count_id%type;
begin
  l_selected := apex_util.string_to_table(:p4_select_lst);
  for i in l_selected.first..l_selected.last loop
    begin
      select count_id
      into   l_county_id
      from   org_county_accountable
      where  organization_id = :p4_id
      and    county_id       = v_county_id;
    exception
      when no_data_found then 
        -- here we have code we only want to execute if there are no dupes already
        -- if not a duplicate record, proceed...
    end;
  end loop;
end;

他のヒント

Oracle 11gは、Cスタイルの「続行」を追加します。 PL / SQLのループ構造。構文的には探しているもののように聞こえます。

あなたの目的のために、なぜループに入る前に重複を排除しないのですか？これは、テーブル関数を使用してl_selectedをクエリし、すべての値を反復処理する代わりに、不要なレコードをフィルタリングすることで実行できます。次のようなもの... 

declare

l_selected APEX_APPLICATION_GLOBAL.VC_ARR2;

cursor no_dups_cur (p_selected APEX_APPLICATION_GLOBAL.VC_ARR2) is 
  select * from (
  select selected.*, 
         count(*) over (partition by county_id) cnt -- analytic to find counts grouped by county_id
    from table(p_selected) selected -- use table function to treat VC_ARR2 like a table 
    ) where cnt = 1 -- remove records that have duplicate county_ids
    ;

begin

l_selected := APEX_UTIL.STRING_TO_TABLE(:P4_SELECT_LIST);

for i in no_dups_cur(l_selected) loop

  null; -- do whatever to non-duplicates 

end loop;

end;

「複製」を決定するためのロジックを置き換えるだけです。あなた自身のもの（あなたの例から本当にその部分に答えるのに十分な情報を持っていませんでした）

NO_DATA_FOUND をキャッチする代わりに、一致するエントリの数を変数（たとえば l_count など）に選択し、このカウントがゼロになったら続行する方法はどうでしょうか。次のようなもの：

    DECLARE
      l_selected APEX_APPLICATION_GLOBAL.VC_ARR2;
      l_count    INTEGER;

      ...snip...
    BEGIN

      -- get the list ids
      l_selected := APEX_UTIL.STRING_TO_TABLE(:P4_SELECT_LIST);
      -- process each in a nice loop
      FOR i IN 1..l_selected.count 
      LOOP
        -- do some data checking stuff...

        -- here we will count duplicate entries, so we can noop if duplicate is found
        SELECT COUNT(*) INTO l_count FROM org_county_accountable
         WHERE organization_id = :P4_ID AND county_id = v_county_id;
        IF l_count = 0 THEN
          -- here we have code we only want to execute if there are no dupes already
          -- if not a duplicate record, proceed...

        END IF;
      END LOOP;
    END;

<xmp>
<<next_loop>>
loop
...
...
if ....
then
   goto next_loop;

</xmp>

これは、GOTOステートメントが 役立つ場合です。 Oracleドキュメントを参照してください。構造を制御して、これを行う方法を確認します。また、ここで検索して、レコードの存在を照会する方法を見つけることもできます。クエリを実行して例外を待つのは最適ではありません。

別の方法-チェックをローカル関数に変換します：

DECLARE
  l_selected APEX_APPLICATION_GLOBAL.VC_ARR2;

  ...snip...
  FUNCTION dup_exists 
     ( p_org_id org_county_accountable.organization_id%TYPE
     , p_county_id org_county_accountable.county_id%TYPE
     ) RETURN BOOLEAN 
  IS
    v_dup_check org_county_accountable.county_id%TYPE;
  BEGIN
    SELECT county_id INTO v_dup_check FROM org_county_accountable
    WHERE organization_id = p_org_id AND county_id = p_county_id;
    RETURN TRUE;
  EXCEPTION WHEN NO_DATA_FOUND THEN
    RETURN FALSE;
  END;
BEGIN

  -- get the list ids
  l_selected := APEX_UTIL.STRING_TO_TABLE(:P4_SELECT_LIST);
  -- process each in a nice loop
  FOR i IN 1..l_selected.count
  LOOP
    -- do some data checking stuff...

    -- here we have code we only want to execute if there are no dupes already
    IF NOT dup_exists (:P4_ID, v_county_id) THEN
      -- if not a duplicate record, proceed...

    END;
  END LOOP;
END;

もちろん、必要に応じてcountメソッドを使用するようにローカル関数を書き直すこともできます。

  FUNCTION dup_exists 
     ( p_org_id org_county_accountable.organization_id%TYPE
     , p_county_id org_county_accountable.county_id%TYPE
     ) RETURN BOOLEAN 
  IS
    l_count INTEGER;
  BEGIN
     SELECT COUNT(*) INTO l_count 
       FROM org_county_accountable
      WHERE organization_id = p_org_id AND county_id = p_county_id;
     RETURN (l_count > 0);
  END;

別の方法は、ユーザー定義の例外を発生させて処理することです：

DECLARE
  l_selected APEX_APPLICATION_GLOBAL.VC_ARR2;
  duplicate_org_county EXCEPTION;

  ...snip...
BEGIN

  -- get the list ids
  l_selected := APEX_UTIL.STRING_TO_TABLE(:P4_SELECT_LIST);
  -- process each in a nice loop
  FOR i IN 1..l_selected.count 
  LOOP
    BEGIN
      -- do some data checking stuff...

      -- here we will look for duplicate entries, so we can noop if duplicate is found
      BEGIN
        SELECT county_id INTO v_dup_check FROM org_county_accountable
        WHERE organization_id = :P4_ID AND county_id = v_county_id;
        RAISE duplicate_org_county;
      EXCEPTION WHEN NO_DATA_FOUND THEN
        dbms_output.put_line('no dups found, proceeding');
      END;
      -- here we have code we only want to execute if there are no dupes already

    EXCEPTION
      WHEN duplicate_org_county THEN NULL;
    END;
  END LOOP;
END;

通常はこれを行いませんが、次のレコードにジャンプする理由が6つ以上ある場合は、複数のネストされたIFよりも望ましい場合があります。

これは古いことは知っていますが、上記の回答ではカーソル属性：

カーソルに関連付けられている属性は、ISOPEN、FOUND、NOTFOUND、およびROWCOUNTの4つです。これらの属性には、％区切り文字を使用してアクセスし、カーソルの状態に関する情報を取得できます。

カーソル属性の構文は次のとおりです。

cursor_name%attribute

ここで、cursor_nameは明示カーソルの名前です。

この場合、次のように目的にROWCOUNT（これまでにフェッチされた行の数を示します）を使用できます。

declare 
   aux number(10) := 0;
   CURSOR cursor_name is select * from table where something;
begin
     select count(*) into aux from table where something;
     FOR row IN cursor_name LOOP
        IF(aux > cursor_name%ROWCOUNT) THEN 'do something is not over';
        ELSE 'do something else';
        END IF;
     END LOOP;
end;
ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top