Open user's library folder using Applescript

Question

I would like to open a folder that defaults to an application's settings folder:

/Users/XXX/Library/Application Support/Tunnelblick/Configurations

I don't want to 'hard code' the 'XXX'.

The /library folder:

set theDestination to (choose folder with prompt "Open destination folder" default location (path to library folder))

The home folder:

set theDestination to (choose folder with prompt "Open destination folder" default location (path to home folder))

I'm not sure how to get the ~/Library folder and one of its subfolders.

Answer 1

The paths to the librarys are:

POSIX path of (path to library folder from user domain)

= ~/Library/

POSIX path of (path to library folder from local domain)

= /Library/

POSIX path of (path to library folder from system domain)

= /System/Library/

Answer 2

The system also knows about the application support folder:

set aFolderPath to ((path to application support folder from user domain) as text) & "Tunnelblick:Configurations:"
try
    set destinationPath to aFolderPath as alias
on error
    beep
    log aFolderPath & " missing"
    return
end try
set theDestination to (choose folder with prompt "Open destination folder" default location destinationPath)

See StandardAdditions, path to

path to v : Return the full path to the specified folder
path to application support/applications folder/desktop/desktop pictures folder/documents folder/downloads folder/favorites folder/Folder Action scripts/fonts/help/home folder/internet plugins/keychain folder/library folder/modem scripts/movies folder/music folder/pictures folder/preferences/printer descriptions/public folder/scripting additions folder/scripts folder/services folder/shared documents/shared libraries/sites folder/startup disk/startup items/system folder/system preferences/temporary items/trash/users folder/utilities folder/workflows folder/voices/apple menu/control panels/control strip modules/extensions/launcher items folder/printer drivers/printmonitor/shutdown folder/speakable items/stationery : the folder to return
[from system domain/local domain/network domain/user domain/Classic domain] : where to look for the indicated folder
[as type class] : the type to return: alias or string (default is alias)
[folder creation boolean] : Create the folder if it doesn’t exist? (default is true)
→ alias : the path to the specified folder

Answer 3

Solved:

set theDefault to (path to home folder as text) & "Library:Application Support:Tunnelblick:Configurations" as alias

set theDestination to (choose folder with prompt "Open destination folder" default location theDefault)