Como faço para transformar um número a uma repetição de caracteres em XSLT?

Question

Eu tenho a seguinte entrada:

<node TEXT="txt">
  <node TEXT="txt">
    <node TEXT="txt"/>
    <node TEXT="txt"/>
  </node>
  <node TEXT="txt"/>
</node>
<node TEXT="txt"/>

Eu estou usando atualmente:

<xsl:number level="multiple" count="node" format="1"/>

dentro de um script XSTL para receber o seguinte resultado:

1 txt
1.1 txt
1.1.1 txt
1.1.2 txt
1.2 txt
2 txt

mas eu quero ter essa saída:

* txt
** txt
*** txt
*** txt
** txt
* txt

Você pode me ajudar?

PS: Eu quero converter um mapa freemind a sintaxe básica lista MediaWiki. E sim! Estou ciente de que há várias maneiras de obter freemind nativa mapeia em wikis mídia, mas eu preciso a conversão do <node>-árvore para *** listas

Answer 1

Uma maneira simples de fazer isso é apenas traduzir o resultado da

<xsl:number/>

para o formato queria.

Esta transformação:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:strip-space elements="*"/>

<xsl:template match="node">
  <xsl:variable name="vIndent">
    <xsl:number level="multiple" count="node"/>
  </xsl:variable>

  <xsl:value-of select=
   "concat(translate($vIndent,
                     '1234567890.',
                     '**********'),
           ' ',
           @TEXT,
         '&#xA;'
         )"/>
 <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

quando aplicado sobre este documento XML:

<t>
    <node TEXT="txt">
        <node TEXT="txt">
            <node TEXT="txt"/>
            <node TEXT="txt"/></node>
        <node TEXT="txt"/></node>
    <node TEXT="txt"/>
</t>

produz o resultado desejado:

* txt
** txt
*** txt
*** txt
** txt
* txt

Observe o uso da função de traduzir () para descartar qualquer "" personagens e para traduzir qualquer dígito em um "*".