encontrando a profundidade máxima do capítulo
Pergunta
todos .Neste caso, quero calcular a profundidade máxima do capítulo. Por exemplo, um livro sem capítulos tem altura 0.Um livro possui apenas capítulos sem seções, a altura deve ser 1. O seguinte é xml:
<book title="D">
<author>
<name>abc</name>
</author>
<chapter title="chapter1">
<section title="section1.1"/>
<section title="section1.2">
<section title="section1.2.1"/>
<section title="section1.2.2"/>
</section>
<section title="section1.3">
<section title="section1.3.1"/>
</section>
</chapter>
<chapter title="chapter2"/>
</book>
A propósito, usei saxão.Quero tentar usar apenas modelos correspondentes. Nesse caso, a saída é texto e o resultado é
3
Este é o meu XSL para calcular a profundidade de cada nota?Está certo? E então como colocar o máximo da moeda chamando um modelo chamado max?
<xsl:transform version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="text" encoding="UTF-8"/>
<xsl:template match="/">
<xsl:apply-templates select="book"/>
<xsl:text> </xsl:text>
</xsl:template>
<xsl:template match="book">
<xsl:apply-templates select="chapter">
<xsl:with-param name ="depth" select ="1"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="chapter|section">
<xsl:param name="depth" as="item()*"/>
<xsl:variable name ="current" select ="$depth"/>
<xsl:sequence select ="$depth"/>
<xsl:if test ="not(empty(section))">
<xsl:apply-templates select="section">
<xsl:with-param name="depth" select="$depth+1"/>
</xsl:apply-templates>
</xsl:if>
</xsl:template>
</xsl:transform >
Solução
E aqui está sua solução - corrigida:
<xsl:transform version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="text" encoding="UTF-8"/>
<xsl:template match="/">
<xsl:variable name="vDepths" as="xs:integer*">
<xsl:apply-templates select="book"/>
</xsl:variable>
<xsl:sequence select="max($vDepths)"/>
</xsl:template>
<xsl:template match="book" as="xs:integer*">
<xsl:apply-templates select="chapter">
<xsl:with-param name ="depth" select ="1"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="chapter|section" as="xs:integer*">
<xsl:param name="depth" as="xs:integer"/>
<xsl:variable name ="current" select ="$depth"/>
<xsl:sequence select ="$depth"/>
<xsl:if test ="not(empty(section))">
<xsl:apply-templates select="section">
<xsl:with-param name="depth" select="$depth+1"/>
</xsl:apply-templates>
</xsl:if>
</xsl:template>
</xsl:transform >
Outras dicas
Solução XSLT 1.0:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:apply-templates select="//*[self::chapter or self::section]">
<xsl:sort data-type="number" order="descending" select=
"count(ancestor::*[self::chapter or self::section])
"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="chapter|section">
<xsl:if test="position()=1">
<xsl:value-of select=
"count(ancestor::*[self::chapter or self::section]) +1
"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
quando esta transformação é aplicada no documento XML fornecido:
<book title="D">
<author>
<name>abc</name>
</author>
<chapter title="chapter1">
<section title="section1.1"/>
<section title="section1.2">
<section title="section1.2.1"/>
<section title="section1.2.2"/></section>
<section title="section1.3">
<section title="section1.3.1"/></section>
</chapter>
<chapter title="chapter2"/>
</book>
a resposta desejada e correta é produzida:
3
Usar:
max(//(chapter|section)/count(ancestor::*[self::chapter or self::section]))+1
Isso pode ser um pouco mais eficiente:
max(//(chapter|section)[not(chapter or section)]
/count(ancestor::*[self::chapter or self::section])
) +1
Licenciado em: CC-BY-SA com atribuição
Não afiliado a StackOverflow