Como posso reorganizar meus dados para ser (x, y) coordenadas para GD :: Graph?

Question

Eu estou escrevendo um programa que leva em um arquivo de entrada do usuário. O arquivo tem monte de números nele e vou ler os números no arquivo e criar um gráfico baseado nesses números usando GD :: Graph .

A primeira linha do ficheiro é do eixo X, segundo a linha de arquivo é Y valores correspondentes ao eixo X e terceiro, quarto, ..., etc Por exemplo:

1 2 3 4 5 
2 4 5 10 14
5 6 8 12 13

Assim, na primeira linha acima, é xaxis, segundo valores de y é correspondente ao eixo x esta vai buscar 10 pontos. (1, 2) (1, 5) (2, 4) (2, 6) .... (4,10) (4,12) (5,14) (5, 13)

I planejar na leitura de cada linha da matriz e, em seguida, dividindo a linha em espaços ou abas e armazenando os valores em uma matriz. Então, array 1 terá eixo x, array2 terá eixo-y, mas como devo guardar 3ª, 4ª, 5ª, ..., etc linhas em uma matriz para que se tornem (x, y)?

Além disso, como posso encontrar o maior valor para as primeira e segunda linhas (2 matrizes) para que eu possa criar um limite para os meus eixos X e Y?

Answer 1

Whoops, mal interpretado a pergunta, você quer tanto um AoAoH ou um AOH, dependendo se cada linha após a primeira representa uma linha ou o são todos os pontos apenas para ser plotados respectivamente. Aqui está como eu iria escrever que se cada linha no arquivo era tornar-se uma linha no gráfico:

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @lines;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @lines, [ 
        map { { x => $x_points[$_], y => $y_points[$_] } }  
    0 .. $#x_points 
    ];
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@lines);

my $i;
for my $line (@lines) {
    $i++;
    print "line $i is made up of points: ",
        (map { "($_->{x}, $_->{y}) " } @$line), "\n";
}

E aqui está como eu iria lidar com isso se eles são pontos apenas para ser plotados:

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @points;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @points,
        map { { x => $x_points[$_], y => $y_points[$_] } }
        0 .. $#x_points;
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@points);

print "Here are the points: ", 
    (map { "($_->{x}, $_->{y}) " } @points), "\n";

Answer 2

Não é realmente uma resposta à sua pergunta, mas não perca GD: :. Graph :: Data

A menos que você é certeza que o primeiro eo último em cada linha é menor / maior que você vai precisar usar algo como Lista :: Util 's min() e max().

---

Eu realmente não entendo o que você quer dizer com "A primeira linha do arquivo é eixo X, segunda linha do arquivo é eixo Y e terceiro, quarto, ..., etc são correspondentes pontos de eixo x."

Answer 3

Você pode crescer seus xey matrizes que você vá.

#!/usr/bin/perl

use Data::Dumper;
use warnings;
use strict;

my @xs = ();
my @ys = ();
my $expecting_xs = 1;
my $last_xs_count;

while(<>) {
  chomp;
  my @values = split(/\s+/);
  if($expecting_xs) {
    push(@xs, @values);
    $last_xs_count = @values;
    $expecting_xs = 0;
  } else {
    if(@values != $last_xs_count) {
      die "Count mismatch";
    } 
    push(@ys, @values);
    $expecting_xs = 1;
  }
}

if(!$expecting_xs) {
  die("Odd number of lines");
}

my($xmin, $xmax) = extremes(@xs);
my($ymin, $ymax) = extremes(@ys);

print "xmin: $xmin xmax: $xmax ymin: $ymin ymax: $ymax\n";
print Dumper(\@xs), Dumper(\@ys);

sub extremes {
  my(@values) = @_;
  return undef unless @values;
  my $min = shift(@values);
  my $max = $min;
  for my $value (@values) {
    $max = $value if $value > $max;
    $min = $value if $value < $min;
  }
  return $min, $max;
}