Notificação Erlang Apple Push não recebendo erro de resposta antes de desconectar

Question

Atualmente estou testando um pouco meu módulo de notificação push.Quando o token do dispositivo é inválido, ele desconecta...

De acordo com Documentação do desenvolvedor de notificação push da Apple Devo receber um pacote de resposta a erros pouco antes de o servidor Apple Push ser desconectado ...

O problema é que eu sou desconectado, mas não recebo nada no Socket antes disso e preciso saber se o push falhou devido a um push malformado (para que eu possa corrigir o bug) ou a um token de dispositivo inválido (então Posso removê-lo do banco de dados).

Aqui está meu código:

-module(pushiphone).
-behaviour(gen_server).

-export([start/1, init/1, handle_call/3, handle_cast/2, code_change/3, handle_info/2, terminate/2]).

-import(ssl, [connect/4]).
-record(push, {socket, state, cert, key}).

start(Provisioning) ->
    gen_server:start_link(?MODULE, [Provisioning], []).

init([Provisioning]) ->
    gen_server:cast(self(), {connect, Provisioning}),
    {ok, #push{}}.

send(Socket, DT, Payload) ->
    PayloadLen = length(Payload),
    DTLen = size(DT),
    PayloadBin = list_to_binary(Payload),
    Packet = <<0:8, 
           DTLen:16/big, 
           DT/binary, 
           PayloadLen:16/big, 
           PayloadBin/binary>>,
    ssl:send(Socket, Packet).

handle_call(_, _, P) ->
    {noreply, P}.

handle_cast({connect, Provisioning}, P) ->
    case Provisioning of
    dev -> Address = "gateway.sandbox.push.apple.com";
    prod -> Address = "gateway.push.apple.com"
    end,
    Port = 2195,
    Cert="/apns-" ++ atom_to_list(Provisioning) ++ "-cert.pem",
    Key="/apns-" ++ atom_to_list(Provisioning) ++ "-key.pem",
    Options = [{certfile, Cert}, {keyfile, Key}, {password, "********"}, {mode, binary}, {active, true}],
    Timeout = 1000,
    {ok, Socket} = ssl:connect(Address, Port, Options, Timeout),
    {noreply, P#push{socket=Socket}};
handle_cast(_, P) ->
    {noreply, P}.

handle_info({ssl, Socket, Data}, P) ->
    <<Command, Status, SomeID:32/big>> = Data,
    io:fwrite("[PUSH][ERROR]: ~p / ~p / ~p~n", [Command, Status, SomeID]),
    ssl:close(Socket),
    {noreply, P};
handle_info({push, message, DT, Badge, [Message]}, P) ->
    Payload = "{\"aps\":{\"alert\":\"" ++ Message ++ "\",\"badge\":" ++ Badge ++ ",\"sound\":\"" ++ "msg.caf" ++ "\"}}",
    send(P#push.socket, DT, Payload),
    {noreply, P};
handle_info({ssl_closed, _SslSocket}, P) ->
    io:fwrite("SSL CLOSED !!!!!!~n"),
    {stop, normal, P};
handle_info(AnythingElse, P) ->
    io:fwrite("[ERROR][PUSH][ANYTHING ELSE] : ~p~n", [AnythingElse]),
    {noreply, P}.

code_change(_, P, _) ->
    {ok, P}.

terminate(_, _) ->
    ok.

Funciona muito bem quando a carga útil e o deviceToken estão corretos.se deviceToken for inválido, ele será desconectado.

Alguém consegue identificar o problema?porque depois de 4 horas de pesquisa, descobri que claramente não consigo!

Aqui está a tabela de resposta a erros:

Status code     Description
0           No errors encountered
1           Processing error
2           Missing device token
3           Missing topic
4           Missing payload
5           Invalid token size
6           Invalid topic size
7           Invalid payload size
8           Invalid token
255         None (unknown)

Answer 1

Você parece estar usando o formato de notificação simples conforme definido pela figura 5-1 na documentação da apple que você vinculou (a julgar pelo seu send() função).Quando esse formato é usado, nenhuma resposta de erro é fornecida quando a solicitação está malformada - você apenas obtém a desconexão.

Para obter a resposta de erro, você deve usar o formato de notificação aprimorado detalhado na figura 5-2.