Tipo de procedimento vinculado como argumentos

Question

Eu quero passar um tipo de dependente de procedimentos (como uma função externa) para outra função, como segue:

module mod1
   implicit none

   type type1
      real :: a
      contains
      procedure,pass :: f
   end type

contains

   real function f(y,e)
      class(type1), intent(in) :: y
      real,intent(in) :: e
      f=y%a+e
   end function

end module

program test

   use mod1
   type(type1) :: t

   t%a=3e0
   write(*,*) s(t%f)

contains

   real function s(g)
      real,external :: g
      s=g(5e0)+2e0
   end function

end program

git produz dá este erro :

       write(*,*) s(t%f)
                       1
Error: Expected argument list at (1)

Mas o que eu posso fazer é:

program test

   t%a=3e0
   write(*,*) s(k)

contains

   real function s(g)
      real,external :: g
      s=g(5e0)+2e0
   end function

   real function k(e)
      real,intent(in) :: e
      k=3e0+e
   end function

end program

Eu acho que o problema está relacionado ao A passagem de tipo dependente procedimentos como argumentos, mas eu não vejo, no momento, como as respostas não pode me ajudar.

EDITAR:

Um exemplo melhor que (espero) mostra a dificuldade:

module mod2
   implicit none
contains

   real function s(g)
       interface
        real function g(x)
          real, intent(in) :: x
        end function
      end interface

      s=g(5e0)+2e0
   end function
end module

module mod1
   use mod2

   type type1
      real :: a
      contains
      procedure,pass :: f
      procedure,pass :: h
   end type

contains

   real function f(y,e)
      class(type1), intent(in) :: y
      real,intent(in) :: e
      f=y%a+e
   end function

   real function h(y)
      class(type1), intent(inout) :: y
      h=s(y%f)
   end function
end module

program test

use mod1
   type(type1) :: t

   t%a=3e0
   write(*,*) t%h
end program

EDIÇÃO II:Ok, os invólucros ainda funcionam em combinação com um ponteiro:

module mod2
   implicit none
contains

   real function s(g)
       interface
        real function g(x)
          real, intent(in) :: x
        end function
      end interface

      s=g(5e0)+2e0
   end function
end module 

module mod1 
   use mod2

   type type1
      real :: a
      contains
      procedure,pass :: f
      procedure,pass :: h
   end type

   class(type1),pointer :: help_w

contains

   real function f(y,e)
      class(type1), intent(in) :: y
      real,intent(in) :: e
      f=y%a+e
   end function

   real function h(y)
      class(type1), intent(inout),target :: y
      help_w => y
      h=s(wrap) 
   end function

   function wrap(x)
      real,intent(in) :: x
      wrap=help_w%f(x)
   end function 
end module

program test

use mod1
   type(type1) :: t

   t%a=3e0
   write(*,*) t%h()
end program

Certamente não é esta uma bela solução, mas pelo menos funciona.

Answer 1

Você pode escrever um wrapper.Este é o mais simples versão.Requer a passagem interna de função como um argumento fictício (F2008), mas você poderia declarar o wrapper em um módulo muito, se o t pode abelha lá.

Nota mudei a declaração de um procedimento de um argumento s para algo mais moderno - o bloco de interface.

program test
   use mod1
   type(type1) :: t

   t%a=3e0
   write(*,*) s(wrap)

contains

   real function s(g)
      interface
        real function g(x)
          real, intent(in) :: x
        end function
      end interface

      s=g(5e0)+2e0
   end function

   function wrap(x)
     real, intent(in) :: x
     wrap = t%f(x)
   end function

end program

A razão para o erro é bem descrito nas respostas vinculadas pergunta, você não pode passar tipo de procedimentos vinculados a maneira que você tentou.