Como faço para modificar eventos AS3 existentes para que eu possa transmitir dados?
-
09-09-2019 - |
Pergunta
Então eu quero uma maneira de configurar eventos para que eu possa transmitir dados sem criar fechamentos \ vazamentos de memória. Isto é, tanto quanto eu tenho:
package com.events {
import flash.events.Event;
public class CustomEvent extends Event {
public static const REMOVED_FROM_STAGE:String = "removedFromStage";
public var data:*;
public function CustomEvent(type:String, customData:*=null, bubbles:Boolean=false, cancelable:Boolean=false) {
super(type, bubbles, cancelable);
this.data = customData;
}
public override function clone():Event {
return new CustomEvent(type, data, bubbles, cancelable);
}
public override function toString():String {
return formatToString("CustomEvent", "type", "data", "bubbles", "cancelable", "eventPhase");
}
}
}
Esta me recebe o seguinte comportamento:
function testme(e:Event) {
trace(e);
}
test_mc.addEventListener(CustomEvent.REMOVED_FROM_STAGE, testme);
test_mc.dispatchEvent(new CustomEvent(CustomEvent.REMOVED_FROM_STAGE, 42));
//Traces [CustomEvent type="removedFromStage" data=42 bubbles=false cancelable=false eventPhase=2]
removeChild(test_mc);
//Traces [Event type="removedFromStage" bubbles=false cancelable=false eventPhase=2]
Meu objetivo é fazer com que os dados personalizados que eu quero passar para conseguir passar do flash dispara evento, não apenas o que eu fogo. Por exemplo, o que se eu queria passar um movieclip juntamente com um evento loader.COMPLETE para colocar o bitmap resultando em?
Solução
Você estendeu a classe Event para que ele despacho com dados extra, agora se você quer a classe Loader despachar o seu tipo de evento personalizado, estender a classe Loader para fazer isso (ou qualquer outra classe que você quer fazer isso com). Neste exemplo eu vou substituir URLLoader com esta funcionalidade (porque carregador realmente despacha eventos a partir dele de contentLoaderInfo, que precisa de duas classes substituídos, e eu só quero mantê-lo simples)
package com.net
{
import flash.net.URLLoader;
import flash.events.Event;
import com.events.CustomEvent;
public class CustomLoader extends URLLoader
{
// URLLoader already has a data property, so I used extraData
public var extraData:*;
override public function dispatchEvent(event: Event) : Boolean
{
var customEvent: CustomEvent = new CustomEvent(event.type, extraData, event.bubbles, event.cancelable);
return super.dispatchEvent(customEvent);
}
}
}
Agora, para usar isso com sua classe CustomEvent tentar este código em seu FLA
import com.net.CustomLoader;
import com.events.CustomEvent;
var loader: CustomLoader = new CustomLoader();
loader.extraData = "Extra Data";
loader.load(new URLRequest("test.xml"));
loader.addEventListener(Event.COMPLETE, loadComplete);
function loadComplete(event: CustomEvent) : void
{
trace(event.data); // Extra Data
}
BAM! dados personalizados em sua inata despachados eventos!
Outras dicas
A seguir mostra a forma mais limpa para criar um evento personalizado. Normalmente tipos de eventos têm referências estáticas públicas digitados em letras do Capitólio. Quando um evento é despachado, passa um evento, ou CustomEvent, objeto para o método de manipulador de eventos. Este é o lugar onde você pode recuperar seu valor passado.
package com.hodgedev.events
{
import flash.events.Event;
public class CustomEvent extends Event
{
public static const VALUE_CHANGED:String = "VALUE_CHANGED";
public var value:Number;
public function CustomEvent(pValue:Number)
{
super(CustomEvent.VALUE_CHANGED);
value = pValue;
}
public override function clone():Event
{
return new CustomEvent(value);
}
}
}
Quando despachar eventos, criamos uma nova instância do evento a ser passado como tal.
private var _someValue:int = 12;
dispatchEvent(new CustomEvent(_somevalue));