Como leio o conteúdo de um diretório em Perl?

Question

Como faço para que o Perl leia o conteúdo de um determinado diretório em um array?

Retrocessos posso fazer isso, mas existe algum método usando 'scandir' ou um termo semelhante?

Answer 1

opendir(D, "/path/to/directory") || die "Can't open directory: $!\n";
while (my $f = readdir(D)) {
    print "\$f = $f\n";
}
closedir(D);

EDITAR:Ah, desculpe, perdi a parte "em um array":

my $d = shift;

opendir(D, "$d") || die "Can't open directory $d: $!\n";
my @list = readdir(D);
closedir(D);

foreach my $f (@list) {
    print "\$f = $f\n";
}

EDITAR2:A maioria das outras respostas são válidas, mas eu queria comentar esta resposta especificamente, em que esta solução é oferecida:

opendir(DIR, $somedir) || die "Can't open directory $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Primeiro, para documentar o que está fazendo, já que o autor da postagem não:está passando a lista retornada de readdir() através de um grep() que retorna apenas os valores que são arquivos (em oposição a diretórios, dispositivos, pipes nomeados, etc.) e que não começam com um ponto (o que torna o nome da lista @dots enganoso, mas isso se deve à alteração que ele fez ao copiá-lo da documentação readdir()).Como limita o conteúdo do diretório retornado, não acho que seja tecnicamente uma resposta correta para essa pergunta, mas ilustra um idioma comum usado para filtrar nomes de arquivos em Perl, e pensei que seria valioso documentar.Outro exemplo muito visto é:

@list = grep !/^\.\.?$/, readdir(D);

Este trecho lê todo o conteúdo do identificador de diretório D exceto '.' e '..', já que esses raramente são desejados para serem usados ​​na listagem.

Answer 2

Uma solução rápida e suja é usar globo

@files = glob ('/path/to/dir/*');

Answer 3

IO::Dir é bom e também fornece uma interface hash vinculada.

Do perldoc:

use IO::Dir;
$d = IO::Dir->new(".");
if (defined $d) {
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

tie %dir, 'IO::Dir', ".";
foreach (keys %dir) {
    print $_, " " , $dir{$_}->size,"\n";
}

Então você poderia fazer algo como:

tie %dir, 'IO::Dir', $directory_name;
my @dirs = keys %dir;

Answer 4

Isso fará isso em uma linha (observe o curinga '*' no final)

@files = </path/to/directory/*>;
# To demonstrate:
print join(", ", @files);

Answer 5

Você poderia usar DirHandle:

use DirHandle;
$d = new DirHandle ".";
if (defined $d)
{
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

DirHandle fornece uma interface alternativa e mais limpa para o opendir(), closedir(), readdir(), e rewinddir() funções.

Answer 6

Aqui está um exemplo de recorrência através de uma estrutura de diretórios e cópia de arquivos de um script de backup que escrevi.

sub copy_directory {
my ($source, $dest) = @_;
my $start = time;

# get the contents of the directory.
opendir(D, $source);
my @f = readdir(D);
closedir(D);

# recurse through the directory structure and copy files.
foreach my $file (@f) {
    # Setup the full path to the source and dest files.
    my $filename = $source . "\\" . $file;
    my $destfile = $dest . "\\" . $file;

    # get the file info for the 2 files.
    my $sourceInfo = stat( $filename );
    my $destInfo = stat( $destfile );

    # make sure the destinatin directory exists.
    mkdir( $dest, 0777 );

    if ($file eq '.' || $file eq '..') {
    } elsif (-d $filename) { # if it's a directory then recurse into it.
        #print "entering $filename\n";
        copy_directory($filename, $destfile); 
    } else { 
        # Only backup the file if it has been created/modified since the last backup 
        if( (not -e $destfile) || ($sourceInfo->mtime > $destInfo->mtime ) ) {
            #print $filename . " -> " . $destfile . "\n";
            copy( $filename, $destfile ) or print "Error copying $filename: $!\n";
        } 
    } 
}

print "$source copied in " . (time - $start) . " seconds.\n";       
}

Answer 7

Semelhante ao acima, mas acho que a melhor versão é (ligeiramente modificada) de "perldoc -f readdir":

opendir(DIR, $somedir) || die "can't opendir $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Answer 8

de: http://perlmeme.org/faqs/file_io/directory_listing.html

#!/usr/bin/perl
use strict;
use warnings;

my $directory = '/tmp';

opendir (DIR, $directory) or die $!;

while (my $file = readdir(DIR)) {
    next if ($file =~ m/^\./);
    print "$file\n";
}

O exemplo a seguir (baseado em um exemplo de código de perldoc -f readdir) obtém todos os arquivos (não diretórios) começando com um ponto final do diretório aberto.Os nomes dos arquivos são encontrados no array @dots.

#!/usr/bin/perl

use strict;
use warnings;

my $dir = '/tmp';

opendir(DIR, $dir) or die $!;

my @dots 
    = grep { 
        /^\./             # Begins with a period
    && -f "$dir/$_"   # and is a file
} readdir(DIR);

# Loop through the array printing out the filenames
foreach my $file (@dots) {
    print "$file\n";
}

closedir(DIR);
exit 0;


closedir(DIR);
exit 0;