Criando um arquivo de lote para fazer backup de uma pasta especificada

Question

Estou realmente muito novo para isso arquivo em lotes. Eu sei que é importante saber pelo menos os comandos básicos. Como posso fazer o seguinte?

• Fechando a pasta especificada.
• Mover a pasta para outro lugar.
• Quando fechando-lo, o nome do arquivo ZIP será a data atual e se houver outro arquivo zipado com o mesmo nome, deve ser nomeado como 20090924-2.

PS : 7-Zip está instalado no meu computador como um software de arquivamento.

Answer 1

O script em lotes listados abaixo irá fazê-lo (eu testei e funciona com as especificações). O diretório para zip e movimento é especificado como seu diretório pai eo nome do o diretório (PARENT_FOLDERTOZIP e FOLDERTOZIP na começando) - eu não conseguia descobrir como copiar todo diretórios (acho XCOPY só pode conteúdo de copiar directórios e sub-directórios.). A localização de cópia é especificada como FOLDERTARGETLOCATION, eo diretório para o local os arquivos compactados é especificado como ZIPDIR.

A localização de 7-Zip é configurado através SEVENZIP_EXE.

Note também que obter a data atual no necessário formato depende do formato de data abreviada em Regional configurações. Eu listei três versões diferentes para ISO-8601, da Europa Central e U.S.A. O único ativo no lista é para o USA (o "set FDATE =" line). Se um um diferente é necessário, em seguida, basta copiar e colar a partir de um dos outros dois.

Dito isto deve-se notar que este tipo de coisa é muito mais fácil com Perl , Python ou PowerShell .

---

@echo off
@title=Folder zip and move...

rem Parameters
  rem Folder to zip and move
    set PARENT_FOLDERTOZIP=T:\to delete
    set FOLDERTOZIP=Folder to Compress

  rem Target folder for moving the input folder to.
    set FOLDERTARGETLOCATION=s:\move Here

  rem Where to place compressed folders
    set ZIPDIR=D:\toDelete\2009-09-24a


rem Configuration
  set SEVENZIP_EXE=D:\Program Files\7-Zip\7z.exe


rem =================== Date ==============================================
rem There is no universal way inside batch itself to get a
rem date that is independent of regional settings (but is
rem quite trivial if an external program or script
rem (Perl/Python) is available).
rem
rem For short date formats:
rem
rem   -------------------------------------------------------
rem
rem   ISO-8601:
rem     0123456789
rem     yyyy-MM-dd/     E.g.: 2009-09-24
rem
rem     set FDATE=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
rem
rem   -------------------------------------------------------
rem
rem   Central european:
rem     0123456789
rem     dd/MM/yyyy     E.g.: 24/09/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
rem
rem   -------------------------------------------------------
rem
rem   US:
rem
rem     0123456789
rem     MM/dd/yyyy     E.g.: 09/24/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~0,2%%DATE:~3,2%

set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
set ZIPFILE=%ZIPDIR%\%FDATE%.7z

set FOLDERTOZIP_FULLPATH=%PARENT_FOLDERTOZIP%\%FOLDERTOZIP%
mkdir %FOLDERTARGETLOCATION%


rem Does a zip file already exist?
if exist "%ZIPFILE%" GOTO L_ZIPFILE_EXISTS
GOTO L_ZIPFILENAME_OK


rem Find a compressed file that does not already exist.
:L_ZIPFILE_EXISTS
set RNUM=0
:L_TRYANOTHER
set /a RNUM=%RNUM% + 1
set ZIPFILE=%ZIPDIR%\%FDATE%-%RNUM%.7z
echo Candidate: %ZIPFILE% ...
if exist "%ZIPFILE%" GOTO L_TRYANOTHER


rem Zip the folder!
:L_ZIPFILENAME_OK
"%SEVENZIP_EXE%"  a %ZIPFILE%   "%FOLDERTOZIP_FULLPATH%"

if exist "%ZIPFILE%" GOTO L_OKZIP
GOTO L_ERROREND


:L_OKZIP
rem Move folder: copy, then delete source.
set DEST_FOLDER=%FOLDERTARGETLOCATION%\%FOLDERTOZIP%
mkdir "%DEST_FOLDER%"
xcopy /Y /S "%FOLDERTOZIP_FULLPATH%"\*.*   "%DEST_FOLDER%"\
rmdir /S "%FOLDERTOZIP_FULLPATH%"
GOTO L_END


:L_ERROREND
echo 7-Zipping failed !!!


:L_END

pause