como classificar um datagrid Flex de acordo com várias colunas?

Question

Eu tenho um datagrid, povoada como mostrado abaixo. Quando o utilizador clica no cabeçalho da coluna, gostaria de classificar as linhas usando uma espécie lexicographic em que a coluna seleccionada é usado pela primeira vez, em seguida, as restantes colunas são usadas em ordem da esquerda para a direita para quebrar quaisquer ligações. Como posso codificar isso?

(eu tenho uma resposta, que eu vou postar abaixo, mas tem um problema - eu vou ser feliz se alguém pode fornecer um melhor)

Aqui está o layout:

<?xml version="1.0" encoding="utf-8"?>

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
    layout="absolute" creationComplete="onCreationComplete()">

    <mx:Script source="GridCode.as" />

    <mx:DataGrid id="theGrid" x="61" y="55" width="466" height="317">
        <mx:columns>
            <mx:DataGridColumn dataField="A"/>
            <mx:DataGridColumn dataField="B"/>
            <mx:DataGridColumn dataField="C"/>
        </mx:columns>
    </mx:DataGrid>

</mx:Application>

E aqui está o código de apoio:

import mx.collections.ArrayCollection;
import mx.collections.Sort;
import mx.collections.SortField;
import mx.controls.dataGridClasses.DataGridColumn;
import mx.events.DataGridEvent;

public function onCreationComplete():void
{
    var ar:ArrayCollection = new ArrayCollection();
    var ob:Object;
    for( var i:int=0; i<20; i++ )
    {
        ob = new Object();
        ob["A"] = i;
        ob["B"] = i%3;
        ob["C"] = i%5;
        ar.addItem(ob);
    }
    this.theGrid.dataProvider = ar;
}

Answer 1

A melhor resposta que eu encontrei até agora é capturar o evento headerRelease quando o usuário clica:

<mx:DataGrid id="theGrid" x="61" y="55" width="466" height="317"
        headerRelease="onHeaderRelease(event)">

O manipulador de eventos pode então aplicar uma ordem de classificação para os dados:

private var lastIndex:int = -1;
private var desc:Boolean = false;

public function onHeaderRelease(evt:DataGridEvent):void
{
    evt.preventDefault();

    var srt:Sort = new Sort();
    var fields:Array = new Array();

    if( evt.columnIndex == lastIndex )
    {
        desc = !desc;
    }
    else
    {
        desc = false;
        lastIndex = evt.columnIndex;
    }

    fields.push( new SortField( evt.dataField, false, desc ) );
    if( evt.dataField != "A" )
        fields.push( new SortField("A", false, desc) );
    if( evt.dataField != "B" )
        fields.push( new SortField("B", false, desc) );
    if( evt.dataField != "C" )
        fields.push( new SortField("C", false, desc) );
    srt.fields = fields;

    var ar:ArrayCollection = this.theGrid.dataProvider as ArrayCollection;
    ar.sort = srt;
    ar.refresh();
}

No entanto, esta abordagem tem um problema bem conhecido, o que é que os cabeçalhos de coluna não exibirá mais pequenas setas para mostrar a direção de classificação. Este é um efeito colateral da chamada evt.preventDefault () no entanto você deve fazer essa chamada ou então a sua classificação personalizada não será aplicada.