manipulação de eventos MSWinsock.Winsock em VisualBasic

Question

Eu estou tentando manipular o evento Winsock_Connect (Na verdade eu preciso dele na macro Excel) usando o seguinte código:

Dim Winsock1 As Winsock 'Object type definition

Sub Init()
    Set Winsock1 = CreateObject("MSWinsock.Winsock") 'Object initialization
    Winsock1.RemoteHost = "MyHost"
    Winsock1.RemotePort = "22"
    Winsock1.Connect

    Do While (Winsock1.State <> sckConnected)
        Sleep 200
    Loop
End Sub

'Callback handler
Private Sub Winsock1_Connect()
    MsgBox "Winsock1::Connect"
End Sub

Mas isso nunca vai para Winsock1_Connect sub-rotina embora Winsock1.State é "Conectado". Eu quero usar a biblioteca MS padrão porque eu não ter direitos administrativos no meu PC e eu não sou capaz de registrar algumas bibliotecas personalizadas. Alguém pode me dizer onde eu estou errado?

Answer 1

Você está preso usando MSWinsock
Aqui é um site / tutorial usando um objeto winsock personalizado.

Além disso ... Você precisa declarar Winsock1 WithEvents dentro de um módulo de "Classe":

Private WithEvents Winsock1 As Winsock

E, finalmente, certifique-se de referenciar o controle winsock ocx.
Ferramentas -> Referências -> Consulta ->% sysem% \ MSWINSCK.OCX

Answer 2

Documentação sobre Winsock Controle :
http://msdn.microsoft.com/en -us / library / aa228119% 28v = vs.60% 29.aspx
Exemplo aqui:
http://support.microsoft.com/kb/163999/en-us

O meu pequeno exemplo com o tratamento de eventos em VBScript:

Dim sock
Set sock = WScript.CreateObject("MSWinsock.Winsock","sock_")
sock.RemoteHost = "www.yandex.com"
sock.RemotePort = "80"
sock.Connect

Dim received
received = 0

Sub sock_Connect()
    WScript.Echo "[sock] Connection Successful!"
    sock.SendData "GET / HTTP/1.1"& vbCrLf & "Host: " & sock.RemoteHost  & vbCrLf & vbCrLf
End Sub

Sub sock_Close()
    WScript.Echo "[sock] Connection closed!"
End Sub

Sub sock_DataArrival(Byval b)
    Dim data
    sock.GetData data, vbString
    received = received + b
    WScript.Echo "---------------------------------------"
    WScript.Echo " Bytes received: " & b  & " ( Total: " & received & " )"
    WScript.Echo "---------------------------------------"
    WScript.Echo data
End Sub

'Wait for server close connection
Do While sock.State <> 8
    rem WScript.Echo sock.State
    WScript.Sleep 1000
Loop

saída será:

cscript /nologo sockhttp.vbs

[sock] Connection Successful!
-------------------------------
 Bytes received: 1376 ( Total: 1376 )
-------------------------------
HTTP/1.1 200 Ok
Date: Mon, 08 Dec 2014 15:41:36 GMT
Content-Type: text/html; charset=UTF-8
Cache-Control: no-cache,no-store,max-age=0,must-revalidate
Expires: Mon, 08 Dec 2014 15:41:36 GMT
...