Como faço para encerrar corretamente um bot :: Basicbot Bot (baseado em Poe :: Component :: IRC)?
Pergunta
Este é um script de amostra. Quando eu bati no Ctrl+C, o bot sai do IRC, mas ele se reconecta depois de algum tempo. Como faço para desligar o bot corretamente?
#!/usr/bin/perl
package main;
my $bot = Perlbot->new (server => 'irc.dal.net');
$SIG{'INT'} = 'Handler';
$SIG{'TERM'} = 'Handler';
sub Handler {
print "\nShutting down bot...\n";
$bot->shutdown('Killed.');
};
$bot->run;
package Perlbot;
use base qw(Bot::BasicBot);
sub connected {
my $self = shift;
$self->join('#codetestchan');
}
Solução
Eu assumi a manutenção do bot :: Basicbot e, na versão 0.82, você pode desligá -lo corretamente com $bot->shutdown($quit_message)
.
Outras dicas
Ao olhar para a documentação e o código -fonte do BOT :: Basicbot, não consigo encontrar uma maneira graciosa de desligá -lo. Como você demonstrou, chamando $bot->shutdown()
(que realmente envia um shutdown
evento para POE::Component::IRC
) só causará Bot::BasicBot
para se reconectar (o mesmo com $bot->quit()
a propósito).
Esta e outras limitações que os usuários se depararam me fizeram recomendar o uso POE::Component::IRC
diretamente. Hoje tem muitos plugins para os recursos fornecidos por Bot::BasicBot
que estavam faltando quando Bot::BasicBot
foi criado. Embora você precise digitar um pouco mais para colocar um bot básico em funcionamento, você tem muito mais flexibilidade. Abaixo está um bot como o do seu exemplo, sem usar Bot::BasicBot
. Ele enviará uma mensagem de saída para o servidor IRC quando você pressionar Ctrl+C, aguarde até que ele tenha sido desconectado e depois saia:
#!/usr/bin/env perl
use strict;
use warnings;
use POE;
use POE::Component::IRC::State;
use POE::Component::IRC::Common qw(parse_user);
use POE::Component::IRC::Plugin::Connector;
use POE::Component::IRC::Plugin::AutoJoin;
# create our session
POE::Session->create(
package_states => [
# event handlers
(__PACKAGE__) => [qw(_start int irc_join irc_disconnected)]
]
);
# start the event loop
POE::Kernel->run();
# session start handler
sub _start {
my ($kernel, $heap) = @_[KERNEL, HEAP];
# handle CTRL+C
$kernel->sig(INT => 'int');
# create bot object
my $irc = POE::Component::IRC::State->spawn(
server => 'irc.freenode.net',
nick => 'basic123bot',
debug => 1,
);
# save $irc in our session's storage heap
$heap->{irc} = $irc;
# handle reconnects
$irc->plugin_add('Connector', POE::Component::IRC::Plugin::Connector->new());
# handle channel joining
$irc->plugin_add('AutoJoin', POE::Component::IRC::Plugin::AutoJoin->new(
Channels => ['#foo123bar'],
));
# connect to IRC
$irc->yield('connect');
}
# interrupt signal handler
sub int {
my ($kernel, $heap) = @_[KERNEL, HEAP];
$heap->{irc}->yield('quit', 'Quitting, bye!');
$heap->{shutting_down} = 1;
$kernel->sig_handled();
}
# join handler
sub irc_join {
my ($who, $chan) = @_[ARG0, ARG1];
my $irc = $_[HEAP]->{irc};
my ($nick, $user, $host) = parse_user($who);
if ($nick eq $irc->nick_name()) {
# say hello to channel members
$irc->yield('privmsg', $chan, 'Hello everybody');
}
}
# disconnect handler
sub irc_disconnected {
my ($heap) = $_[HEAP];
# shut down if we disconnected voluntarily
$heap->{irc}->yield('shutdown') if $heap->{shutting_down};
}