Tabela de modo de organização para expressões S

Question

Eu gostaria de exportar de tabelas de modo de organização para as expressões S.

| first  | second | thrid  |
|--------+--------+--------|
| value1 | value2 | value3 |
| value4 | value5 | value6 |

Se transformaria em:

((:FIRST "value1" :SECOND "value2" :THIRD "value3")
 (:FIRST "value4" :SECOND "value5" :THIRD "value6"))

Eu pretendo escrever uma configuração tão se ela ainda não existir, mas achei que eu tocaria no StackOverflow antes de começar a reinventar a roda.

Answer 1

Isso faz o truque. Tem uma verificação mínima de erro.

A interface a ser usada é a interface programática:

(org-table-to-sexp <location-of-beginning-of-table> <location-of-end-of-table>)

Nesse caso, retornará o sexo que você solicitou.

Se você quiser um uso interativo, pode chamar o seguinte comando para operar na tabela no região. Então, defina a marca no início da tabela, vá até o final e digite:

M-x insert-org-table-to-sexp

Isso inserirá o Sexp desejado imediatamente após a tabela no buffer atual.

Aqui está o código:

(defun org-table-to-sexp-parse-line ()
  "Helper, returns the current line as a list of strings"
  (save-excursion
    (save-match-data
      (let ((result nil)
            (end-of-line (save-excursion (end-of-line) (point))))
        (beginning-of-line)
        (while (re-search-forward "\\([^|]*\\)|" end-of-line t)
          (let ((match (mapconcat 'identity (split-string (match-string-no-properties 1)) " ")))
            (if (< 0 (length match))
                ;; really want to strip spaces from front and back
                (push match result))))
        (reverse result)))))

(require 'cl)
(defun org-table-to-sexp (b e)
  "Parse an org-mode table to sexp"
  (save-excursion
    (save-match-data
      (goto-char b)
      (let ((headers (mapcar
                      (lambda (str)
                        (make-symbol (concat ":" (upcase str))))
                      (org-table-to-sexp-parse-line)))
            (sexp nil))
        (forward-line 1)                ;skip |--+--+--| line
        (while (< (point) e)
          (forward-line 1)
          (let ((line-result nil))
            (mapcar* (lambda (h e)
                       (push h line-result)
                       (push e line-result))
                     headers
                     (org-table-to-sexp-parse-line))
            (if line-result
                (push (reverse line-result)
                      sexp))))
        sexp))))

(defun insert-org-table-to-sexp (b e)
  "Convert the table specified by the region and insert the sexp after the table"
  (interactive "r")
  (goto-char (max b e))
  (print (org-table-to-sexp b e) (current-buffer)))