Interrupção estendida 13, lendo um disco não formado

Question

Já faz um tempo desde que fiz algum ASM e decidi mais uma vez tentar escrever um pequeno carregador de inicialização, testando com Qemu. Meu problema é com o Interrupt 13, por algum motivo, o sinalizador de transporte está sendo definido, então a leitura está falhando. Atualmente, minha imagem de disco se parece:

512 Byte Bootloader <- este (até onde estou ciente) é o bloco 0 em LBA

Função principal <- este seria o Bloco 1

Basicamente, com os 512 bytes que o BIOS carrega na memória, quero carregar os próximos 512 bytes da mesma unidade. Não consigo descobrir o que está dando errado no entanto. Espero ter fornecido informações suficientes.

Aqui está o código, o problema é com a segunda interrupção 0x13, pouco antes do salto para 0x7E00:

[bits 16]
[org 0x7C00]

; Prepare Stack Segment
;-----------------------------------------------------------------
    mov sp, 0x7A00              ; Move Stack into SP
    mov bp, sp                  ; Store current Stack Base

; Print Character to Make Sure Bootloader Has Reached this Point
;-----------------------------------------------------------------
    mov ah, 0x0E                ; Print Character to Screen
    mov bh, 0x00                ; No Page Numbering
    mov bl, 0x07                ; White Text, Black Background
    mov al, 65                  ; Print Letter A
    int 0x10

; Check if INT0x13 Extentions are Supported
;-----------------------------------------------------------------
    mov ah, 0x41                ; Set Function 0x41
    mov word bx, 0x55AA          
    push dx                     ; Save old Drive Identifier
    mov dl, 0x80                ; Load 'Active' ID Into dl
    int 0x13                    ; Call Interupt
    jc short unsupported        ; If Extentions aren't Supported, Jump
    xor ax, ax
    add ax, 1                   ; Clear Carry Bit

    mov si, DAPS                ; Load DAPS Struct to DS:SI
    mov ah, 0x42                ; Read Functions (AL Ignored)
    mov dl, 0x80                ; Active Boot Drive (Commented Out Due to Line 24)
    int 0x13
    jc short unsupported        ; If something goes wrong...
    jmp 0x7E00                  ; Jump to main

; Errors 
;-----------------------------------------------------------------
    unsupported:
    mov ah, 0x0E                ; Print Letter F, Gives Indication of Failure
    mov bh, 0x00
    mov bl, 0x07
    mov al, 70
    int 0x10

    success:
    pop dx                      ; Pop Original Drive Identifier
    jmp $

; Fill Out Rest of Bootloader
;-----------------------------------------------------------------
times 494-($-$$) db 0

; Memory Data Structures and Other Variables
;-----------------------------------------------------------------
    ; Disk Address Packet Structure (Used For Loading Rest of OS)
    DAPS: db 0x10               ; Size of Structure (16 bytes)
          db 0                  ; Always 0
          db 1                  ; Number of Sectors to Read (1x512)
          db 0                  ; Always 0 
          dw 0x7E00             ; Target Location for Reading To
          dw 0                  ; Page Table (0, Disabled)
          dd 1                  ; Read from Second Block
          dd 0                  ; Large LBAs, ignore

    db 0x55, 0xAA               ; Add Boot Record Signature

main:
    mov ah, 0x0E                ; Print Character to Screen
    mov bh, 0x00                ; No Page Numbering
    mov bl, 0x07                ; White Text, Black Background
    mov al, 66                  ; Print Letter B
    int 0x10

    jmp $

Answer 1

O problema acabou sendo simples, o código estava certo. Mas como a imagem final era de 525 bytes, em vez de um múltiplo de 512 bytes, a leitura quebrou. Só tive que fazer minha imagem com 0s para fazer o tamanho da imagem 1024b para que a leitura pudesse obter todos os 512 bytes.

(Obviamente provavelmente uma ideia muito melhor para não ter um pequeno disco não formado como este, mas para fins de aprendizado, isso é tudo o que eu realmente precisava)