Enumerando a lista de DSN é criado em um computador

Question

Eu tenho um aplicativo Excel em que eu quero apresentar ao usuário uma lista da fonte nomes de dados (ou seja: do DSN)., Em que ele / ela pode escolher o que fonte de dados para uso

Esperamos que uma vez eu tenho a lista, eu posso facilmente acessar as propriedades DSN para se conectar ao banco de dados apropriado.

Por favor note, eu faço não quiser usar uma conexão DSN-less.

Answer 1

As entradas DSN são armazenadas no registro nas seguintes chaves.

HKEY_CURRENT_USER\Software\ODBC\ODBC.INI\ODBC Data Sources
HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources

Este contém a lista de todos os DSN definido. Isso funciona como um índice global e os detalhes específicos para cada DSN são armazenados em uma chave com o nome DSN em:

HKEY_CURRENT_USER\Software\ODBC\ODBC.INI
HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI

Criar algumas entradas em ambos os Usuários guias DSN e DSN de sistema de fontes de dados (ODBC) applet do painel de controle e verifique como esses valores são armazenados no registro.

O exemplo seguinte enumerar o DSN definidas para o utilizador da calha do painel de controlo> Ferramentas administrativas> Fontes de Dados (ODBC) [DSN de utilizador Tab].

http://support.microsoft.com/kb/178755

  Option Explicit

  Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
      Alias "RegOpenKeyExA" _
      (ByVal hKey As Long, _
      ByVal lpSubKey As String, _
      ByVal ulOptions As Long, _
      ByVal samDesired As Long, phkResult As Long) As Long

  Private Declare Function RegEnumValue Lib "advapi32.dll" _
      Alias "RegEnumValueA" _
      (ByVal hKey As Long, _
      ByVal dwIndex As Long, _
      ByVal lpValueName As String, _
      lpcbValueName As Long, _
      ByVal lpReserved As Long, _
      lpType As Long, _
      lpData As Any, _
      lpcbData As Long) As Long

  Private Declare Function RegCloseKey Lib "advapi32.dll" _
      (ByVal hKey As Long) As Long

  Const HKEY_CLASSES_ROOT = &H80000000
  Const HKEY_CURRENT_USER = &H80000001
  Const HKEY_LOCAL_MACHINE = &H80000002
  Const HKEY_USERS = &H80000003

  Const ERROR_SUCCESS = 0&

  Const SYNCHRONIZE = &H100000
  Const STANDARD_RIGHTS_READ = &H20000
  Const STANDARD_RIGHTS_WRITE = &H20000
  Const STANDARD_RIGHTS_EXECUTE = &H20000
  Const STANDARD_RIGHTS_REQUIRED = &HF0000
  Const STANDARD_RIGHTS_ALL = &H1F0000
  Const KEY_QUERY_VALUE = &H1
  Const KEY_SET_VALUE = &H2
  Const KEY_CREATE_SUB_KEY = &H4
  Const KEY_ENUMERATE_SUB_KEYS = &H8
  Const KEY_NOTIFY = &H10
  Const KEY_CREATE_LINK = &H20
  Const KEY_READ = ((STANDARD_RIGHTS_READ Or _
                    KEY_QUERY_VALUE Or _
                    KEY_ENUMERATE_SUB_KEYS Or _
                    KEY_NOTIFY) And _
                    (Not SYNCHRONIZE))

  Const REG_DWORD = 4
  Const REG_BINARY = 3
  Const REG_SZ = 1

  Private Sub Command1_Click()
     Dim lngKeyHandle As Long
     Dim lngResult As Long
     Dim lngCurIdx As Long
     Dim strValue As String
     Dim lngValueLen As Long
     Dim lngData As Long
     Dim lngDataLen As Long
     Dim strResult As String

     lngResult = RegOpenKeyEx(HKEY_CURRENT_USER, _
             "SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources", _
              0&, _
              KEY_READ, _
              lngKeyHandle)

     If lngResult <> ERROR_SUCCESS Then
         MsgBox "Cannot open key"
         Exit Sub
     End If

     lngCurIdx = 0
     Do
        lngValueLen = 2000
        strValue = String(lngValueLen, 0)
        lngDataLen = 2000

        lngResult = RegEnumValue(lngKeyHandle, _
                                 lngCurIdx, _
                                 ByVal strValue, _
                                 lngValueLen, _
                                 0&, _
                                 REG_DWORD, _
                                 ByVal lngData, _
                                 lngDataLen)
        lngCurIdx = lngCurIdx + 1

        If lngResult = ERROR_SUCCESS Then
           strResult = strResult & lngCurIdx & ": " & Left(strValue, lngValueLen) & vbCrLf
        End If
     Loop While lngResult = ERROR_SUCCESS
     Call RegCloseKey(lngKeyHandle)

     Call MsgBox(strResult, vbInformation)
  End Sub

Answer 2

Você pode usar o SQLDataSources função da API ODBC. Consulte MSDN documentação .

Answer 3

extremamente cool solução. Corri para um problema onde CURRENT_USER não estava mostrando todo o DSN de, certamente não o que eu precisava. Eu mudei para LOCAL_MACHINE e viu toda DSN do que apareceu no Gerenciador de Conexão, incluindo o subconjunto que apareceu sob CURRENT_USER.

http: // MSDN .microsoft.com / en-us / library / janelas / desktop / ms712603 (v = VS.85) .aspx