Como posso serializar um fechamento em Perl?

Question

Eu acho que isso pode ser melhor perguntado usando um exemplo:

use strict;
use warnings;
use 5.010;
use Storable qw(nstore retrieve);

local $Storable::Deparse = 1;
local $Storable::Eval    = 1;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001
nstore( $sub, "/tmp/sub.store" );
$sub = retrieve("/tmp/sub.store");
say $sub->(1); # gives 1

Quando eu despejo /tmp/sub.store Eu vejo:

$VAR1 = sub {
            package Storable;
            use warnings;
            use strict 'refs';
            my($y) = @_;
            return $x + $y;
        }

Mas $x nunca é definido neste sub. Eu esperaria que o sub -gerado por sub_generator terá $x substituído por seu valor real na geração. Como devo resolver isso?

Observe que esta pergunta está relacionada a isso 1.

Answer 1

Infelizmente eu não acho Storable trabalha com fechamentos. No entanto, existem outros módulos da CPAN que seriam em serializar um fechamento. Para por exemplo. Data::Dump::Streamer

use 5.012;
use warnings;
use Data::Dump::Streamer;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001

my $serialised = Dump( $sub )->Out;
my $copy = do {
    my $CODE1 = undef;
    eval $serialised;
    $CODE1;
};

say $copy->(2); # gives 1002
say $sub->(1);  # still gives 1001

É assim que o código serializado se parece quando impresso aqui, say Dump $sub;:

my ($x);
$x = 1000;
$CODE1 = sub {
           use warnings;
           use strict 'refs';
           BEGIN {
             $^H{'feature_unicode'} = q(1);
             $^H{'feature_say'} = q(1);
             $^H{'feature_state'} = q(1);
             $^H{'feature_switch'} = q(1);
           }
           my($y) = @_;
           return $x + $y;
         };

Atualizar

Veja este tópico Armazenável e fechamento na lista de discussão do Perl5 Porters. Confirma o que eu pensava sobre Storable e fechamentos.

/I3az/