Como posso inserir a data e hora atual em um arquivo usando Emacs?
-
05-07-2019 - |
Pergunta
O que ordena em Emacs eu posso usar para inserir no buffer de texto de um arquivo a data e hora atual?
(Por exemplo, o equivalente no bloco de notas é simplesmente pressionando F5 que é sobre o recurso só é útil para o bloco de notas!)
Solução
C-u M-! date
Outras dicas
Coloque no seu arquivo .emacs:
;; ====================
;; insert date and time
(defvar current-date-time-format "%a %b %d %H:%M:%S %Z %Y"
"Format of date to insert with `insert-current-date-time' func
See help of `format-time-string' for possible replacements")
(defvar current-time-format "%a %H:%M:%S"
"Format of date to insert with `insert-current-time' func.
Note the weekly scope of the command's precision.")
(defun insert-current-date-time ()
"insert the current date and time into current buffer.
Uses `current-date-time-format' for the formatting the date/time."
(interactive)
(insert "==========\n")
; (insert (let () (comment-start)))
(insert (format-time-string current-date-time-format (current-time)))
(insert "\n")
)
(defun insert-current-time ()
"insert the current time (1-week scope) into the current buffer."
(interactive)
(insert (format-time-string current-time-format (current-time)))
(insert "\n")
)
(global-set-key "\C-c\C-d" 'insert-current-date-time)
(global-set-key "\C-c\C-t" 'insert-current-time)
Eu usei esses trechos curtos:
(defun now ()
"Insert string for the current time formatted like '2:34 PM'."
(interactive) ; permit invocation in minibuffer
(insert (format-time-string "%D %-I:%M %p")))
(defun today ()
"Insert string for today's date nicely formatted in American style,
e.g. Sunday, September 17, 2000."
(interactive) ; permit invocation in minibuffer
(insert (format-time-string "%A, %B %e, %Y")))
Eles vieram originalmente journal.el
Você pode instalar yasnippet , que vai deixar você digitar "tempo" e a tecla tab e faz muito mais além. Ele apenas chama current-time-string
nos bastidores, para que possa controlar a utilização format-time-string
formatação.
Para inserir data:
M-x org-time-stamp
Para o tempo de inserir data:
C-u M-x org-time-stamp
Você pode vincular uma chave global para este comando.
O método de org-mode
é muito amigável, você pode selecionar qualquer data de calendário.
Aqui está um pacote que eu escrevi há um tempo atrás que faz o que você está pedindo.
http://github.com/rmm5t /insert-time.el/tree/master/insert-time.el
(require 'insert-time)
(define-key global-map [(control c)(d)] 'insert-date-time)
(define-key global-map [(control c)(control v)(d)] 'insert-personal-time-stamp)
M-1 M-! data ??p>
isso faz com que o comando shell você correr para ser inserido no tampão que você está editando em vez de um novo buffer.
Obrigado, CMS! Meu variação, para o que vale a pena - faz-me bastante feliz:
(defvar bjk-timestamp-format "%Y-%m-%d %H:%M"
"Format of date to insert with `bjk-timestamp' function
%Y-%m-%d %H:%M will produce something of the form YYYY-MM-DD HH:MM
Do C-h f on `format-time-string' for more info")
(defun bjk-timestamp ()
"Insert a timestamp at the current point.
Note no attempt to go to beginning of line and no added carriage return.
Uses `bjk-timestamp-format' for formatting the date/time."
(interactive)
(insert (format-time-string bjk-timestamp-format (current-time)))
)
Eu coloquei isso em um arquivo que é chamado pelo meu .emacs usando:
(load "c:/bjk/elisp/bjk-timestamp.el")
que tanto o torna mais fácil de modificar sem o risco de quebrar alguma coisa em meu .emacs, e permitiu-me um ponto de entrada fácil para talvez um dia realmente aprendendo o que esta programação Emacs Lisp é tudo.
P.S. Críticas sobre minha n00b técnica mais bem-vindos.
Para uma resposta semelhante à que já foram postados, juntamente com explicações e mais extensões como abrir automaticamente um arquivo e inserir a data atual, no final do mesmo (como um diário), veja discussão de seus utilitários emacs de Paulo Ford .
Aqui está a minha opinião sobre ele.
(defun modi/insert-time-stamp (option)
"Insert date, time, user name - DWIM.
If the point is NOT in a comment/string, the time stamp is inserted prefixed
with `comment-start' characters.
If the point is IN a comment/string, the time stamp is inserted without the
`comment-start' characters. If the time stamp is not being inserted immediately
after the `comment-start' characters (followed by optional space),
the time stamp is inserted with “--” prefix.
If the buffer is in a major mode where `comment-start' var is nil, no prefix is
added regardless.
Additional control:
C-u -> Only `comment-start'/`--' prefixes are NOT inserted
C-u C-u -> Only user name is NOT inserted
C-u C-u C-u -> Both prefix and user name are not inserted."
(interactive "P")
(let ((current-date-time-format "%a %b %d %H:%M:%S %Z %Y"))
;; Insert a space if there is no space to the left of the current point
;; and it's not at the beginning of a line
(when (and (not (looking-back "^ *"))
(not (looking-back " ")))
(insert " "))
;; Insert prefix only if `comment-start' is defined for the major mode
(when (stringp comment-start)
(if (or (nth 3 (syntax-ppss)) ; string
(nth 4 (syntax-ppss))) ; comment
;; If the point is already in a comment/string
(progn
;; If the point is not immediately after `comment-start' chars
;; (followed by optional space)
(when (and (not (or (equal option '(4)) ; C-u or C-u C-u C-u
(equal option '(64))))
(not (looking-back (concat comment-start " *")))
(not (looking-back "^ *")))
(insert "--")))
;; If the point is NOT in a comment
(progn
(when (not (or (equal option '(4)) ; C-u or C-u C-u C-u
(equal option '(64))))
(insert comment-start)))))
;; Insert a space if there is no space to the left of the current point
;; and it's not at the beginning of a line
(when (and (not (looking-back "^ *"))
(not (looking-back " ")))
(insert " "))
(insert (format-time-string current-date-time-format (current-time)))
(when (not (equal option '(16))) ; C-u C-u
(insert (concat " - " (getenv "USER"))))
;; Insert a space after the time stamp if not at the end of the line
(when (not (looking-at " *$"))
(insert " "))))
Eu prefiro ligar isto a C-c d
.