Alterar um valor namespace em uma transformação XSL?

Question

Eu não tenho certeza se isso é possível, como eu sou muito novo para XSLT e outras coisas, mas talvez alguns de vocês poderiam me ajudar aqui? É um pouco complicado e eu não encontrei nada parecido na internet:

O problema é que eu tenho um xml de entrada com namespaces declarados e tudo e eu só precisa fazer pequenas mudanças a ele (adicionando ou excluindo atributos, ou transferindo-os para outros locais). Mas, ao mesmo tempo, eu tenho que atualizar as referências de namespace na tag documento do documento. Assim, por exemplo, o XML de entrada pode ser algo como isto:

<order
  xmlns="some.url.01"
  xmlns:ns2="some.other.url"
  xmlns:ns3="another.one"
>
  <orderEntry>
    <orderControl>
      <mandant>test</mandant>
      <businessUnit>test</businessUnit>
      <inboundChannel>test</inboundChannel>
      <timestamp>timestamp</timestamp>
      <requestedDocuments>
        <ns2:document>orderForm</ns2:document>
      </requestedDocuments>
    </orderControl>
  </orderEntry>
</order>

o XML resultante deve ser semelhante a este:

<order
  xmlns="some.url.02"
  xmlns:ns2="some.other.url.02"
  xmlns:ns3="another.one.02"
>
  <orderEntry>
    <orderControl>
      <mandant>test</mandant>
      <businessUnit>test</businessUnit>
      <inboundChannel>test</inboundChannel>
      <!-- deleted timestamp for example -->
      <requestedDocuments>
        <ns2:document>orderForm</ns2:document>
      </requestedDocuments>
    </orderControl>
  </orderEntry>
</order>

mas a única coisa que eu vejo é:

<order
  xmlns="some.url.02"
>
  <orderEntry>
    <orderControl>
      <mandant>test</mandant>
      <businessUnit>test</businessUnit>
      <inboundChannel>test</inboundChannel>
      <!-- deleted timestamp for example -->
      <requestedDocuments>
        <ns2:document xmlns:ns2="some.other.url.02">orderForm</ns2:document>
      </requestedDocuments>
    </orderControl>
  </orderEntry>
</order>

Agora, talvez por um ou dois de você, pode não ser que tratam um grande, mas eu tenho a restrição de que o documento de saída deve olhar one-to-one o mesmo que o documento de entrada, exceto para as alterações solicitadas (mudanças de namespace e eliminação).

Meu XSLT parece um como este:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns="some.url.02"
  xmlns:ns2="some.other.url.02"
  xmlns:ns3="another.one.02"
>
  <xsl:output method="xml" version="1.0" encoding="UTF-8" standalone="yes" indent="yes"/>

  <xsl:strip-space elements="*"/>

  <xsl:template match="*">
    <xsl:choose>
      <xsl:when test="name(.) != 'timestamp'">
        <xsl:element name="{node-name(.)}">
          <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
      </xsl:when>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:attribute name="{node-name(.)}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

Pode alguém por favor ajuda? Namespaces são complicados: (

P.S .: Quem editou a minha entrada: Thanks:)

Answer 1

Você pode definir o namespace no elemento de saída com o atributo namespace:

<xsl:element name="{node-name(.)}" namespace="http://www.bar.org">
  // ...
</xsl:element>

Note que o namespace deve ser um URI e embora eu espero que você sabe que este é provavelmente uma boa idéia para URIs usar em seu exemplo.

Aqui está um link para o excelente tutorial Zvon que tem exemplos trabalhados: http://www.zvon.org/xxl/XSLTreference/Output/xslt_element_namespace. html

Eu concordo que namespaces são complicados. Como você sabe o prefixo é semanticamente irrelevante, mas muitos sistemas permitem que você escolha o seu prefixo por razões estéticas. Também olhar Saxon ( http://saxon.sourceforge.net/ )

Editar Eu acho que você vai encontrar aqui a sua resposta: em vez de elemento de atributo namespace

Answer 2

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns:ns1_src="some.url.01"
  xmlns:ns2_src="some.other.url"
  xmlns:ns3_src="another.one"
  xmlns="some.url.02"
  xmlns:ns2="some.other.url.02"
  xmlns:ns3="another.one.02"
>
  <!-- 
    Note that all the source namespaces got their own new "*_src" prefix. 
    The target namespaces take over the original prefixes. 
    "some.url.02" is the new global namespace.
  -->

  <xsl:output method="xml" version="1.0" encoding="UTF-8" standalone="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <!-- the identity template to copy everything, unless 
       it has been declared otherwise -->
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
  </xsl:template>

  <!-- three templates to handle elements -->
  <xsl:template match="ns1_src:*">
    <xsl:element name="{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="ns2_src:*">
    <xsl:element name="ns2:{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="ns3_src:*">
    <xsl:element name="ns3:{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <!-- three templates to handle attributes -->
  <xsl:template match="@ns1_src:*">
    <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="@ns2_src:*">
    <xsl:attribute name="ns2:{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="@ns3_src:*">
    <xsl:attribute name="ns3:{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <!-- timestamps will be ignored -->
  <xsl:template match="ns1_src:timestamp" />

</xsl:stylesheet>

Output:

<order xmlns="some.url.02">
  <orderEntry>
    <orderControl>
      <mandant>test</mandant>
      <businessUnit>test</businessUnit>
      <inboundChannel>test</inboundChannel>
      <requestedDocuments>
        <ns2:document xmlns:ns2="some.other.url.02">orderForm</ns2:document>
      </requestedDocuments>
    </orderControl>
  </orderEntry>
</order>

Answer 3

<xsl:template match="a:*">
  <xsl:element name="{local-name()}"
               namespace="http://example.com/B">
    <xsl:copy-of select="@*" />
    <xsl:apply-templates />
  </xsl:element>
</xsl:template>

Ele procura por qualquer elemento no namespace com a prefixo e substitui-lo com um elemento com o mesmo nome de http://example.com/B namespace. Todos os atributos são copiados 'como é' e, em seguida, todas as crianças são avaliadas.

Adicionar o seu tratamento personalizado ou em torno de que, conforme necessário.

Answer 4

Você está usando tarefa XSLT do Ant para fazer a sua transformação?

Se a resposta for sim, você pode querer mudar a partir do motor XSLT padrão que vem com Sun JDK 1.5+. Leia este .

Além disso, leia este artigo sobre namespaces em XSLT