De quantas maneiras diferentes existem para concatenar dois arquivos linha por linha usando Perl?
-
06-07-2019 - |
Pergunta
FILE1 olhares Suponha como este:
bye bye hello thank you
E arq2 esta aparência:
chao hola gracias
A saída desejada é esta:
bye bye chao hello hola thank you gracias
Eu mesmo já vêm-se com cinco abordagens diferentes para resolver este problema. Mas eu acho que deve haver outras maneiras, provavelmente, mais concisa e formas mais elegantes, e eu espero que eu possa aprender mais coisas legais:)
O seguinte é o que eu tentei até agora, com base no que eu aprendi com as muitas soluções de meus problemas anteriores. Além disso, eu estou tentando classificar de digest ou internalizar o conhecimento que adquiri do livro lama.
Código 1:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)){
die "Files are different sizes!\n" unless eof(file1) == eof(file2);
$line1 .= $line2;
$line1 =~ s/\n/ /;
print "$line1 \n";
}
Código 2:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
my @file1 = <$file1>;
open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;
for (my $n=0; $n<=$#file1; $n++) {
$file1[$n] .=$file2[$n];
$file1[$n]=~s/\n/ /;
print $file1[$n];
}
Código 3:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
my %hash;
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)) {
chomp $line1;
chomp $line2;
my ($key, $val) = ($line1,$line2);
$hash{$key} = $val;
}
print map { "$_ $hash{$_}\n" } sort keys %hash;
Código 4:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)) {
$line1 =~ s/(.+)/$1 $line2/;
print $line1;
}
Código 5:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
my @file1 =<$file1>;
open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;
while ((@file1) && (@file2)){
my $m = shift (@file1);
chomp($m);
my $n = shift (@file2);
chomp($n);
$m .=" ".$n;
print "$m \n";
}
Eu tentei algo como isto:
foreach $file1 (@file2) && foreach $file2 (@file2) {...}
Mas Perl me deu um aviso de erro sintáctico. Eu estava frustrado. Mas podemos executar duas voltas foreach
simultaneamente?
Obrigado, como sempre, para quaisquer comentários, sugestões e, claro, a partilha de códigos generoso:)
Solução
Isso funciona para qualquer número de arquivos:
use strict;
use warnings;
use autodie;
my @handles = map { open my $h, '<', $_; $h } @ARGV;
while (@handles){
@handles = grep { ! eof $_ } @handles;
my @lines = map { my $v = <$_>; chomp $v; $v } @handles;
print join(' ', @lines), "\n";
}
close $_ for @handles;
Outras dicas
A maneira mais elegante não envolve perl
em tudo:
paste -d' ' file1 file2
Se eu fosse um homem de golfe, eu poderia reescrever @ do FM resposta como:
($,,$\)=(' ',"\n");@_=@ARGV;open $_,$_ for @_;print
map{chomp($a=<$_>);$a} @_=grep{!eof $_} @_ while @_
que você pode ser capaz de se transformar em um one-liner mas isso é apenas o mal. ; -)
Bem, aqui está, com menos de 100 caracteres:
C:\Temp> perl -le "$,=' ';@_=@ARGV;open $_,$_ for @_;print map{chomp($a =<$_>);$a} @_=grep{!eof $_ }@_ while @_" file1 file2
Se é OK para gole (e por que diabos não - nós são à procura de maneiras diferentes), eu acho que eu descobri o caminho da insanidade:
@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof
and $.=0 while<>;print "@$_{@_}\n" for @x
C:\Temp> perl -e "@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof and $.=0 while<>;print qq{@$_{@_}\n} for @x" file1 file2
Output:
bye bye chao hello hola thank you gracias
Uma alternativa mais fácil para o seu Código 5 que permite a um número arbitrário de linhas e não se importa se os arquivos têm diferentes números de linhas (chapéu de ponta @FM):
#!/usr/bin/perl
use strict; use warnings;
use File::Slurp;
use List::AllUtils qw( each_arrayref );
my @lines = map [ read_file $_ ], @ARGV;
my $it = each_arrayref @lines;
while ( my @lines = grep { defined and chomp and length } $it->() ) {
print join(' ', @lines), "\n";
}
E, sem o uso de quaisquer módulos externos:
#!perl
use autodie; use warnings; use strict;
my ($file1, $file2) = @ARGV;
open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;
open my $file2_h,'<', $file2;
my @file2 = grep { chomp; length } <$file2_h>;
my $n_lines = @file1 > @file2 ? @file1 : @file2;
for my $i (0 .. $n_lines - 1) {
my ($line1, $line2) = map {
defined $_ ? $_ : ''
} $file1[$i], $file2[$i];
print $line1, ' ', $line2, "\n";
}
Se você quiser concatenar apenas as linhas que aparecem em ambos os arquivos:
#!perl
use autodie; use warnings; use strict;
my ($file1, $file2) = @ARGV;
open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;
open my $file2_h,'<', $file2;
my @file2 = grep { chomp; length } <$file2_h>;
my $n_lines = @file1 < @file2 ? @file1 : @file2;
for my $i (0 .. $n_lines - 1) {
print $file1[$i], ' ', $file2[$i], "\n";
}
Um fácil com o mínimo de verificação de erros:
#!/usr/bin/perl -w
use strict;
open FILE1, '<file1.txt';
open FILE2, '<file2.txt';
while (defined(my $one = <FILE1>) or defined(my $twotemp = <FILE2>)){
my $two = $twotemp ? $twotemp : <FILE2>;
chomp $one if ($one);
chomp $two if ($two);
print ''.($one ? "$one " : '').($two ? $two : '')."\n";
}
E não, você não pode executar dois loops simultânea dentro do mesmo segmento, você teria que fork
, mas isso não seria garantido para ser executado de forma síncrona.