Напишите персонаж в видео буфера

Question

Я пытаюсь написать букву «D» синим цветом на белом фоне, перемещая ее в видео буфер. Что не так с этим кодом?

INCLUDE Irvine16.inc

.code
main PROC

mov ax,@data
mov ds,ax

mov si, 0b800h
mov word ptr [si], 44h
mov word ptr [si+2] 0701h

mov ah, 08h
int 21h

exit

main ENDP

Внес изменения выше. Теперь он собирается, но ничего не отображает.

Answer 1

Пример примера:

name "hello-world"
org 100h

; set video mode     
mov ax, 3     ; text mode 80x25, 16 colors, 8 pages (ah=0, al=3) 
int 10h       ; do it! 

; cancel blinking and enable all 16 colors: 
mov ax, 1003h
mov bx, 0
int 10h


; set segment register: 
mov     ax, 0b800h
mov     ds, ax

; print "hello world" 
; first byte is ascii code, second byte is color code. 

mov [02h], 'h'

mov [04h], 'e'

mov [06h], 'l'

mov [08h], 'l'

mov [0ah], 'o'

mov [0ch], ','

mov [0eh], 'w'

mov [10h], 'o'

mov [12h], 'r'

mov [14h], 'l'

mov [16h], 'd'

mov [18h], '!'




; color all characters: 
mov cx, 12  ; number of characters. 
mov di, 03h ; start from byte after 'h' 

c:  mov [di], 11101100b   ; light red(1100) on yellow(1110) 
    add di, 2 ; skip over next ascii code in vga memory. 
    loop c

; wait for any key press: 
mov ah, 0
int 16h

ret

Надеюсь, этот образец поможет вам

Answer 2

1) 0B800H - это сегмент Адрес видео буфера. mov word ptr [si], 44h адреса только компенсировать (здесь: 0B800H) адреса сегмента в DS - а также DSне указывает на видео буфер. Я предлагаю загрузить видео -сегмент в ES и использовать переопределение сегмента (ES:).

2) Письмо плюс цветная форма вместе слово. В видео буфере сначала появляется буква, затем цвет. Фон и цвет переднего плана Используйте каждый кусок (4 бит). Из -за «Маленькой эндсианности» (Google для него) слово должно иметь цвет/буква формата, например, белый/синий/'d' = 7144H

Это совместимый пример IRVINE16:

INCLUDE Irvine16.inc
INCLUDELIB Irvine16.lib

.CODE
main PROC
;   mov ax,@data                ; No .DATA in this example
;   mov ds,ax

    mov si, 0b800h              ; Initialize ES with video buffer
    mov es, si

    xor si, si                  ; Position 0 is top left
    mov word ptr es:[si], 7144h ; White background ('7'), blue foreground (1), letter 'D' (44)

    mov ah, 08h                 ; Wait for key - http://www.ctyme.com/intr/rb-2561.htm
    int 21h

    exit                        ; Irvine16: end of program
main ENDP

END main

Answer 3

Посмотрите на листинг 15 здесь:

http://stuff.pypt.lt/ggt80x86a/asm8.htm