Sort Assocatiative Array с Awk
Вопрос
Вот мой массив (скрипт Gawk):
myArray["peter"] = 32
myArray["bob"] = 5
myArray["john"] = 463
myArray["jack"] = 11
После сортировки мне нужен следующий результат:
bob 5
jack 11
peter 32
john 463
Когда я использую «Asort», индексы теряются. Как сортировать по значению массива без потери индексов? (Мне нужны упорядоченные индексы на основе их значений)
(Мне нужно получить этот результат только с Awk/Gawk, а не сценарием оболочки, Perl и т. Д.)
Если мой пост недостаточно ясен, вот другой пост, объясняющий ту же проблему: http://www.experts-exchange.com/programming/languages/scripting/shell/q_26626841.html )
заранее спасибо
Обновлять :
Спасибо вам обоим, но мне нужно сортировать по значениям, а не индексам (я хочу упорядоченные индексы в соответствии с их значениями).
В других терминах мне нужен этот результат:
bob 5
jack 11
peter 32
john 463
нет :
bob 5
jack 11
john 463
peter 32
(Я согласен, мой пример сбивает с толку, выбранные значения довольно плохие)
Из Кодекса Catcall я написал быструю реализацию, которая работает, но она довольно уродливо (я объединяю ключи и значения перед сортировкой и разделением во время сравнения). Вот как это выглядит:
function qsort(A, left, right, i, last) {
if (left >= right)
return
swap(A, left, left+int((right-left+1)*rand()))
last = left
for (i = left+1; i <= right; i++)
if (getPart(A[i], "value") < getPart(A[left], "value"))
swap(A, ++last, i)
swap(A, left, last)
qsort(A, left, last-1)
qsort(A, last+1, right)
}
function swap(A, i, j, t) {
t = A[i]; A[i] = A[j]; A[j] = t
}
function getPart(str, part) {
if (part == "key")
return substr(str, 1, index(str, "#")-1)
if (part == "value")
return substr(str, index(str, "#")+1, length(str))+0
return
}
BEGIN { }
{ }
END {
myArray["peter"] = 32
myArray["bob"] = 5
myArray["john"] = 463
myArray["jack"] = 11
for (key in myArray)
sortvalues[j++] = key "#" myArray[key]
qsort(sortvalues, 0, length(myArray));
for (i = 1; i <= length(myArray); i++)
print getPart(sortvalues[i], "key"), getPart(sortvalues[i], "value")
}
Конечно, мне интересно, если у вас есть что -то более чистое ...
Спасибо за ваше время
Решение
Редактировать:
Сортировать по значениям
Ой! Чтобы сортировать ценности, это немного kludge, но вы можете создать временный массив, используя объединение значений и индексы исходного массива в качестве индексов в новом массиве. Тогда ты можешь asorti()
Временный массив и разделил конкатенированные значения обратно на индексы и значения. Если вы не можете следовать этому запутанному описанию, код намного проще понять. Это также очень короткое.
# right justify the integers into space-padded strings and cat the index
# to create the new index
for (i in myArray) tmpidx[sprintf("%12s", myArray[i]),i] = i
num = asorti(tmpidx)
j = 0
for (i=1; i<=num; i++) {
split(tmpidx[i], tmp, SUBSEP)
indices[++j] = tmp[2] # tmp[2] is the name
}
for (i=1; i<=num; i++) print indices[i], myArray[indices[i]]
РЕДАКТИРОВАТЬ 2:
Если у вас есть Gawk 4, вы можете пройти массив по порядку значений, не выполняя явную сортировку:
#!/usr/bin/awk -f
BEGIN {
myArray["peter"] = 32
myArray["bob"] = 5
myArray["john"] = 463
myArray["jack"] = 11
PROCINFO["sorted_in"] = "@val_num_asc"
for (i in myArray) {
{print i, myArray[i]}}
}
}
Существуют настройки для прохождения по индексу или значению, восходящему или нисходящему и другим параметрам. Вы также можете указать пользовательскую функцию.
Предыдущий ответ:
Сортировка по индексам
Если у вас есть AWK, например gawk
3.1.2 или выше, что поддерживает asorti()
:
#!/usr/bin/awk -f
BEGIN {
myArray["peter"] = 32
myArray["bob"] = 5
myArray["john"] = 463
myArray["jack"] = 11
num = asorti(myArray, indices)
for (i=1; i<=num; i++) print indices[i], myArray[indices[i]]
}
Если у вас нет asorti()
:
#!/usr/bin/awk -f
BEGIN {
myArray["peter"] = 32
myArray["bob"] = 5
myArray["john"] = 463
myArray["jack"] = 11
for (i in myArray) indices[++j] = i
num = asort(indices)
for (i=1; i<=num; i++) print i, indices[i], myArray[indices[i]]
}
Другие советы
Используйте команду Sort Sort с трубой, сохраняет код AWK и следуйте философии UNIX
Создайте входной файл со значениями, разделенными запятыми
Петр, 32
Джек, 11
Джон, 463
Боб, 5
Создайте файл sort.awk с кодом
BEGIN { FS=","; }
{
myArray[$1]=$2;
}
END {
for (name in myArray)
printf ("%s,%d\n", name, myArray[name]) | "sort -t, -k2 -n"
}
Запустите программу, должен дать вам выход
$ awk -f sort.awk данные
Боб, 5
Джек, 11
Петр, 32
Джон, 463
PROCINFO["sorted_in"] = "@val_num_desc";
Перед итерацией массива используйте приведенное выше оператор. Но он работает в версии AWK 4.0.1. Это не работает в версии AWK 3.1.7.
Я не уверен, в какой промежуточной версии она была представлена.
И простой ответ ...
function sort_by_myArray(i1, v1, i2, v2) {
return myArray[i2] < myArray[i1];
}
BEGIN {
myArray["peter"] = 32;
myArray["bob"] = 5;
myArray["john"] = 463;
myArray["jack"] = 11;
len = length(myArray);
asorti(myArray, k, "sort_by_myArray");
# Print result.
for(n = 1; n <= len; ++n) {
print k[n], myArray[k[n]]
}
}
Авторы Язык программирования AWK обеспечить функция QuickSort, который доступен в Интернете.
Я думаю, что вы сделаете что -то подобное.
END {
for (key in myArray) {
sortkeys[j++] = key;
}
qsort(sortkeys, 0, length(myArray)); # Not sure I got the args right.
for (i = 1; i <= length(myArray); i++) {
print sortkeys[i], myArray[sortkeys[i]];
}
}