Как устранить ошибку Adobe Flex: & # 8220; Ошибка # 2036: загрузка никогда не завершена & # 8221 ;?

Question

Как устранить ошибку Adobe Flex: " Ошибка № 2036: загрузка никогда не завершена "?

Answer 1

Проблема была в неправильном расположении модулей SWF. Как только будет установлено подходящее место для сгенерированных модулей SWF - ошибка исчезнет.

Answer 2

Не забывайте, что вы также можете добавить IOErrorEvent-listener к загрузчикам, чтобы вы могли отслеживать немного больше информации для себя. Приведенный ниже код является общим началом, и ему, вероятно, потребуется немного больше информации, прежде чем он на самом деле будет работать во flash / flex.

swfLoaderInstance:SWFLoader = new SWFLoader();
swfLoaderInstance.source = "someSWFFile.swf";
swfLoaderInstance.addEventListener(IOErrorEvent.IO_ERROR, handleError);

public function handleError(event:IOErrorEvent):void{
    trace(event.target);
    //etc...
}

Answer 3

Если это интернет-браузер, и вы используете Google Chrome. Перейдите на страницу History > Очистить все данные для просмотра Отметьте только это, вы не захотите потерять данные просмотра.

Очистить кеш, Удалить куки и другие данные сайта и плагина, Очистить сохраненные данные формы автозаполнения

Очистить это с начала времен. Затем попробуйте загрузить то, что вы хотите. У меня сработало нормально :)

Answer 4

У меня было то же сообщение об ошибке. В моем случае это было связано с тем, что Loader собирал мусор.

Это код, с которым у меня были проблемы:

private function loadImageFromUrl( imageUrl:String ):AbstractOperation
    {
        var result:AbstractOperation = new AbstractOperation();

        var loader:Loader = new Loader();
        loader.contentLoaderInfo.addEventListener( Event.COMPLETE, function ( e:Event ):void
        {
            result.dispatchCompleteEvent( loader.content );
        } );
        loader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, function ( event:IOErrorEvent ):void
        {
            result.dispatchErrorEvent( event );
        } );
        loader.load( new URLRequest( imageUrl ) );

        return result;
    }

И это хороший код:

private var m_loaderReferences:Dictionary = new Dictionary();

private function loadImageFromUrl( imageUrl:String ):AbstractOperation
    {
        var result:AbstractOperation = new AbstractOperation();

        var loader:Loader = new Loader();
        m_loaderReferences[imageUrl] = loader; // Need to keep a reference to the loader to avoid Garbage Collection
        loader.contentLoaderInfo.addEventListener( Event.COMPLETE, function ( e:Event ):void
        {
            result.dispatchCompleteEvent( loader.content );
            delete m_loaderReferences[imageUrl];
        } );
        loader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, function ( event:IOErrorEvent ):void
        {
            result.dispatchErrorEvent( event );
            delete m_loaderReferences[imageUrl];
        } );
        loader.load( new URLRequest( imageUrl ) );

        return result;
    }

Я ссылаюсь на загрузчик из словаря, чтобы избежать GC. Я удаляю загрузчик из Словаря, когда загрузка будет завершена.