LEFT JOIN in SAS using PROC SQL

Question 1

Joe is right, you need to take also ID into consideration, but with his solution you cannot get 2nd March 2012 because no one is trading that day. You can do everything with just one sql step (which will take a bit longer):

proc sql;
   create table final as
   select d.trading_date, d.ID, t.Price, t.Ret
   from
   (
      select trading_date, ID 
      from table_a, (select distinct ID from table_b) 
   ) d
   left join
   (
      select *
      from table_b
   ) t
   on t.Date=d.trading_date and t.ID=d.ID
   order by d.id, d.trading_date;
quit;

Question 2

Your left join doesn't work since it doesn't take ID into account. SAS (or rather SQL) doesn't know that it should repeat by ID.

The easiest way to get the full combination is PROC FREQ with SPARSE, assuming someone has a trade on every valid trading day.

proc freq data=table_b noprint;
tables id*trading_date/sparse out=table_all(keep=id trading_date);
run;

Then join that to the original table_b by id and date.

Alternately, you can use PROC MEANS, which can get your numerics (it can't get characters this way, unless you can use them as a class value).

Using table_b as created by Anton (With ret and price variables):

proc means data=table_b noprint completetypes nway;
class id trading_date;
var ret price;
output out=table_allmeans sum=;
run;

This will output missing for missing rows and values for present rows, and will have a _FREQ_ variable that allows you to differentiate whether a row is really present in the trading dataset or not.

Question 3

I suppose there must be something off with the data because your query looks fine and worked on the testing data I generated along the lines you described:

data table_a;
    format trading_date date9.;
    do trading_date= "01MAR2012"d to "06MAR2012"d;
        output;
    end;
run;

data table_b;
    format date date9.;
    ret = 0;
    price = 0;
    do date= "01MAR2012"d to "06MAR2012"d;
        do ID = 1 to 4;
            if ranuni(123) < 0.3 then
                output;
        end;
    end;
run;

Below is what I get after running your query copied verbatim:

trading_date date ret price ID 
01MAR2012 01MAR2012 0 0 3 
02MAR2012 02MAR2012 0 0 2 
03MAR2012 03MAR2012 0 0 1 
03MAR2012 03MAR2012 0 0 2 
04MAR2012 04MAR2012 0 0 2 
05MAR2012 05MAR2012 0 0 3 
06MAR2012 . . . .

It is worth checking the format of your dates- are they numeric? If they are character, are they formatted the same way? If they are numeric, are they dates or datetimes with some odd format applied?