Недостаточно оцененный контекст внутри предложения `with`

Question

Я застрял на следующем доказательстве.

module Temp where

   open import Data.Empty
   open import Data.Fin hiding (compare)
   open import Data.Nat hiding (compare); open import Data.Nat.Properties
   open import Function
   open import Level
   open import Relation.Binary
   open import Relation.Binary.PropositionalEquality

Я работаю с натуральными числами Γ, интерпретируемыми как контексты, а-ля индексы де Брейна и использование элементов Fin Γ в качестве идентификаторов.(Для целей моего вопроса не обязательно понимать их как контексты и идентификаторы, но это может помочь с интуицией.)

Переименование - это контекстный морфизм:

   Ren : Rel ℕ Level.zero
   Ren Γ Γ′ = Fin Γ → Fin Γ′

Теперь я определяю следующие две очень простые операции.Первый, close-var, приводит к переименованию, которое удаляет имя из контекста, сопоставляя его с существующим именем в оставшемся контексте.Второй, open-var, приводит к переименованию, которое выполняет обратное, вставляя новое имя в контекст в определенном месте.Чтобы найти точку вставки или удаления в контексте, я сравниваю на toℕ, поскольку я еще не разобрался, как использовать Data.Fin.compare.

   open StrictTotalOrder strictTotalOrder
   open DecTotalOrder decTotalOrder renaming (refl to ≤-refl; trans to ≤-trans)
   open import Data.Fin.Props using (bounded)

   close-var : ∀ {Γ} → Fin Γ → Fin (suc Γ) → Fin (suc Γ) → Fin Γ
   close-var _ y z with compare (toℕ y) (toℕ z)
   close-var _ _ zero | tri< () _ _
   close-var _ _ (suc z) | tri< _ _ _ = z
   close-var x _ _ | tri≈ _ _ _ = x
   close-var _ zero _ | tri> _ _ ()
   close-var _ (suc y) z | tri> _ _ z<suc-y = 
      fromℕ≤ (≤-trans z<suc-y (bounded y))

   open-var : ∀ {Γ} → Fin (suc Γ) → Fin Γ → Fin (suc Γ)
   open-var y z with compare (toℕ y) (toℕ z)
   ... | tri< _ _ _ = suc z
   ... | tri≈ _ _ _ = suc z
   ... | tri> _ _ _ = inject₁ z

Единственной нетривиальной частью этих определений является последний случай close-var который должен переходить от большего контекста к меньшему.

Для фиксированных аргументов переименования, полученные из close-var и open-var образуют изоморфизм (я совершенно уверен).Однако я застрял в осмыслении следующих целей:

   close∘open≡id : ∀ {Γ} (x : Fin Γ) (y : Fin (suc Γ)) (z : Fin Γ) → 
                   (close-var x y ∘ open-var y) z ≡ z
   close∘open≡id _ y z with compare (toℕ y) (toℕ z)
   close∘open≡id _ y z | tri< _ _ _ with compare (toℕ y) (suc (toℕ z))
   close∘open≡id _ _ _ | tri< _ _ _ | tri< _ _ _ = refl
   close∘open≡id _ _ _ | tri< y<z _ _ | tri≈ y≮suc-z _ _ = 
      ⊥-elim (y≮suc-z (≤-step y<z))
   close∘open≡id _ _ _ | tri< y<z _ _ | tri> y≮suc-z _ _ = 
      ⊥-elim (y≮suc-z (≤-step y<z))
   close∘open≡id _ y z | tri≈ _ _ _ with compare (toℕ y) (suc (toℕ z))
   close∘open≡id _ _ _ | tri≈ _ _ _ | tri< _ _ _ = refl
   close∘open≡id _ _ _ | tri≈ _ y≡z _ | tri≈ y≮suc-z _ _ rewrite y≡z = 
      ⊥-elim (y≮suc-z ≤-refl)
   close∘open≡id _ _ _ | tri≈ _ y≡z _ | tri> y≮suc-z _ _ = {!!}
   close∘open≡id _ y z | tri> _ _ _ with compare (toℕ y) (toℕ (inject₁ z))
   close∘open≡id _ _ _ | tri> _ _ _ | tri< _ _ _ = {!!}
   close∘open≡id _ _ _ | tri> _ _ _ | tri≈ _ _ _ = {!!}
   close∘open≡id _ _ _ | tri> _ _ _ | tri> _ _ _ = {!!}

Первый случай должен быть невозможен, но я, кажется, не могу использовать y≡z и y≮suc-z чтобы вывести противоречие, как я сделал в непосредственно предыдущем случае.Я думаю, это потому, что сам шаблон абсурден, но я не знаю, как убедить в этом Агду.

Вторая и, возможно, связанная с этим проблема заключается в том, что, похоже, не произошло достаточного сокращения в рамках четырех оставшихся целей.Все они содержат with такие паттерны, как tri< .a .¬b .¬c.Но я ожидал, что вложенный with положения, допускающие достаточное исполнение для их устранения.Что я делаю не так?

(В качестве проверки на вменяемость это легко проверить:

   sub : ∀ {Γ} (x : Fin Γ) (y : Fin (suc Γ)) → Ren Γ Γ
   sub x y = close-var x y ∘ open-var y

   Γ : ℕ
   Γ = 5

   ρ : Ren Γ Γ
   ρ = sub (suc (zero)) (suc (suc (suc zero)))

   ex₁ : ρ zero ≡ zero
   ex₁ = refl

   ex₂ : ρ (suc zero) ≡ suc zero
   ex₂ = refl

   ex₃ : ρ (suc (suc (zero))) ≡ suc (suc zero)
   ex₃ = refl

   ex₄ : ρ (suc (suc (suc (zero)))) ≡ suc (suc (suc zero))
   ex₄ = refl

и так далее.)

Answer 1

Вложенный with оговорки - это нормально.Проблема в том, что в определении close-var, вы подходите не только по результату compare (toℕ y) (toℕ z), но и на аргументах y и z самих себя.И, конечно, Agda не может что-то уменьшить, не будучи уверенным, какое функциональное уравнение использовать.

Во втором отверстии, close-var должен ли шаблон совпадать на inject₁ z, но вы этого не делаете (и не можете).Вы также должны абстрагироваться от этого, а затем сопоставить шаблон в достаточной степени, чтобы убедить Agda в том, что он может безопасно выбрать одно уравнение.

close∘open≡id x y z | tri> _ _ _
  with inject₁ z | compare (toℕ y) (toℕ (inject₁ z))
... | tri> _ _ _ | Fin.zero  | tri< () _ _
... | tri> _ _ _ | Fin.suc r | tri< _  _ _ = {!!}  -- goal is r ≡ z

---

Что касается первой дыры - если приведенный выше код не помогает, просто докажите простую лемму:

≡→≤ : {x y : ℕ} → x ≡ y → x ≤ y
≡→≤ refl = ≤-refl

И тогда вы можете вывести противоречие с помощью:

y≮suc-z (s≤s (≡→≤ y≡z))

(Я не заглядывал в StrictTotalOrder записи, но есть вероятность, что эта лемма уже существует).